From 616579b5d773c50af31ee56f00105d96ce641ca2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Aug 2021 10:30:13 +0100
Subject: gentoo resync : 14.08.2021

---
 www-apps/drupal/drupal-7.82-r1.ebuild | 58 +++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 www-apps/drupal/drupal-7.82-r1.ebuild

(limited to 'www-apps/drupal/drupal-7.82-r1.ebuild')

diff --git a/www-apps/drupal/drupal-7.82-r1.ebuild b/www-apps/drupal/drupal-7.82-r1.ebuild
new file mode 100644
index 000000000000..fab5db976ab2
--- /dev/null
+++ b/www-apps/drupal/drupal-7.82-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit webapp
+
+MY_PV=${PV:0:3}.0
+
+DESCRIPTION="PHP-based open-source platform and content management system"
+HOMEPAGE="https://www.drupal.org/"
+SRC_URI="https://ftp.drupal.org/files/projects/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+IUSE="+mysql postgres sqlite +uploadprogress"
+
+RDEPEND="
+	dev-lang/php[gd,hash(+),mysql?,pdo,postgres?,simplexml,sqlite?,xml]
+	virtual/httpd-php
+	uploadprogress? ( dev-php/pecl-uploadprogress )
+"
+
+need_httpd_cgi
+
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+src_install() {
+	webapp_src_preinst
+
+	local docs="MAINTAINERS.txt LICENSE.txt INSTALL.txt CHANGELOG.txt INSTALL.mysql.txt INSTALL.pgsql.txt INSTALL.sqlite.txt UPGRADE.txt "
+	dodoc ${docs}
+	rm -f ${docs} INSTALL COPYRIGHT.txt || die
+
+	cp sites/default/{default.settings.php,settings.php} || die
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	dodir "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default/settings.php
+
+	webapp_configfile "${MY_HTDOCSDIR}"/sites/default/settings.php
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	echo
+	ewarn "SECURITY NOTICE"
+	ewarn "If you plan on using SSL on your Drupal site, please consult the postinstall information:"
+	ewarn "\t# webapp-config --show-postinst ${PN} ${PV}"
+	echo
+}
-- 
cgit v1.2.3