From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 www-apps/davical/davical-1.1.10.ebuild | 72 ++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 www-apps/davical/davical-1.1.10.ebuild

(limited to 'www-apps/davical/davical-1.1.10.ebuild')

diff --git a/www-apps/davical/davical-1.1.10.ebuild b/www-apps/davical/davical-1.1.10.ebuild
new file mode 100644
index 000000000000..55191dde88dd
--- /dev/null
+++ b/www-apps/davical/davical-1.1.10.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature webapp
+
+DESCRIPTION="A CalDAV and CardDAV Server"
+HOMEPAGE="https://www.davical.org/"
+SRC_URI="https://www.davical.org/downloads/${PN}_${PV}.orig.tar.xz -> ${P}.tar.xz"
+
+LICENSE="GPL-2 GPL-2+ GPL-3+ LGPL-2.1+ LGPL-3+"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="sys-devel/gettext"
+
+RDEPEND="app-admin/pwgen
+	dev-lang/php[calendar,curl,iconv,imap,nls,pdo,postgres,xml]
+	dev-perl/DBD-Pg
+	dev-perl/DBI
+	dev-perl/YAML
+	>=dev-php/awl-0.62
+	virtual/httpd-php"
+
+need_httpd
+
+S="${WORKDIR}"
+
+src_compile() {
+	emake built-locale
+}
+
+src_install() {
+	webapp_src_preinst
+
+	einstalldocs
+
+	einfo "Installing web files"
+	insinto "${MY_HTDOCSDIR}"
+	doins -r htdocs/. htdocs/.htaccess
+
+	einfo "Installing main files and i18n"
+	insinto "${MY_HOSTROOTDIR}/${PN}"
+	doins -r inc locale
+	rm "${ED}/${MY_HOSTROOTDIR}/${PN}/inc/always.php.in" || die
+
+	einfo "Installing sql files"
+	insinto "${MY_SQLSCRIPTSDIR}"
+	doins -r dba/.
+
+	insinto /etc/${PN}
+	doins -r config/. "${FILESDIR}/vhost-example"
+
+	webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"
+	webapp_postupgrade_txt en "${FILESDIR}/postupgrade-en.txt"
+	webapp_src_install
+
+	fperms +x "${MY_SQLSCRIPTSDIR}/create-database.sh"
+	fperms +x "${MY_SQLSCRIPTSDIR}/update-davical-database"
+}
+
+pkg_postinst() {
+	elog "If you are upgrading from a previous version of davical, don't forget to"
+	elog "upgrade the database structure with"
+	elog "       cd /usr/share/webapps/davical/${PVR}/sqlscripts/"
+	elog "       ./update-davical-database -dbuser xxxxxxx -appuser xxxxxx"
+
+	webapp_pkg_postinst
+
+	elog ""
+	optfeature "LDAP authentication" dev-lang/php[ldap]
+}
-- 
cgit v1.2.3