From 491d0101c89d81dec507f28215b3cb094800d600 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 22 Jun 2024 00:11:38 +0100
Subject: gentoo auto-resync : 22:06:2024 - 00:11:37

---
 sys-process/nmon/nmon-16q.ebuild | 57 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 sys-process/nmon/nmon-16q.ebuild

(limited to 'sys-process/nmon/nmon-16q.ebuild')

diff --git a/sys-process/nmon/nmon-16q.ebuild b/sys-process/nmon/nmon-16q.ebuild
new file mode 100644
index 000000000000..3f39fe737fa2
--- /dev/null
+++ b/sys-process/nmon/nmon-16q.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+MY_P="lmon${PV}"
+DESCRIPTION="Nigel's performance MONitor for CPU, memory, network, disks, etc"
+HOMEPAGE="http://nmon.sourceforge.net/"
+SRC_URI="https://downloads.sourceforge.net/${PN}/${MY_P}.c"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="sys-libs/ncurses:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-16n-musl.patch
+)
+
+src_unpack() {
+	cp "${DISTDIR}"/${MY_P}.c "${S}"/${PN}.c || die
+}
+
+src_configure() {
+	local cflags=(
+		# Recommended by upstream to be always on
+		-DGETUSER
+		-DJFS
+		-DLARGEMEM
+		-DKERNEL_2_6_18
+
+		# Arches
+		$(usex amd64 -DX86 '')
+		$(usex x86 -DX86 '')
+		$(usex arm -DARM '')
+		$(usex ppc64 -DPOWER '')
+	)
+
+	append-cflags "${cflags[@]}"
+	append-libs "$($(tc-getPKG_CONFIG) --libs ncurses) -lm"
+}
+
+src_compile() {
+	tc-export CC
+
+	emake ${PN} LDLIBS="${LIBS}"
+}
+
+src_install() {
+	dobin ${PN}
+}
-- 
cgit v1.2.3