From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 sys-process/nmon/nmon-16n.ebuild | 57 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 sys-process/nmon/nmon-16n.ebuild

(limited to 'sys-process/nmon/nmon-16n.ebuild')

diff --git a/sys-process/nmon/nmon-16n.ebuild b/sys-process/nmon/nmon-16n.ebuild
new file mode 100644
index 000000000000..1aee09867d35
--- /dev/null
+++ b/sys-process/nmon/nmon-16n.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+MY_P="lmon${PV}"
+DESCRIPTION="Nigel's performance MONitor for CPU, memory, network, disks, etc"
+HOMEPAGE="http://nmon.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.c"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="sys-libs/ncurses:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-16n-musl.patch
+)
+
+src_unpack() {
+	cp "${DISTDIR}"/${MY_P}.c "${S}"/${PN}.c || die
+}
+
+src_configure() {
+	local cflags=(
+		# Recommended by upstream to be always on
+		-DGETUSER
+		-DJFS
+		-DLARGEMEM
+		-DKERNEL_2_6_18
+
+		# Arches
+		$(usex amd64 -DX86 '')
+		$(usex x86 -DX86 '')
+		$(usex arm -DARM '')
+		$(usex ppc64 -DPOWER '')
+	)
+
+	append-cflags "${cflags[@]}"
+	append-libs "$($(tc-getPKG_CONFIG) --libs ncurses) -lm"
+}
+
+src_compile() {
+	tc-export CC
+
+	emake ${PN} LDLIBS="${LIBS}"
+}
+
+src_install() {
+	dobin ${PN}
+}
-- 
cgit v1.2.3