From b8f9cc8d0880d028eb7536742f0042580b55a72e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 17 Jan 2023 23:55:47 +0000
Subject: gentoo auto-resync : 17:01:2023 - 23:55:47

---
 sys-process/lsof/lsof-4.97.0.ebuild | 58 +++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 sys-process/lsof/lsof-4.97.0.ebuild

(limited to 'sys-process/lsof/lsof-4.97.0.ebuild')

diff --git a/sys-process/lsof/lsof-4.97.0.ebuild b/sys-process/lsof/lsof-4.97.0.ebuild
new file mode 100644
index 000000000000..ad7040fcc803
--- /dev/null
+++ b/sys-process/lsof/lsof-4.97.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+MY_P="${P/-/_}"
+DESCRIPTION="Lists open files for running Unix processes"
+HOMEPAGE="https://github.com/lsof-org/lsof"
+SRC_URI="https://github.com/lsof-org/lsof/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="lsof"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="rpc selinux"
+
+RDEPEND="
+	rpc? ( net-libs/libtirpc )
+	selinux? ( sys-libs/libselinux )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-apps/groff
+	rpc? ( virtual/pkgconfig )
+"
+
+# Needs fixing first
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	export ac_cv_header_rpc_rpc_h=$(usex rpc)
+	export ac_cv_header_selinux_selinux_h=$(usex selinux)
+
+	[[ ${CHOST} == *-solaris2.11 ]] && append-cppflags -DHAS_PAD_MUTEX
+
+	econf
+}
+
+src_compile() {
+	emake DEBUG="" all
+}
+
+pkg_postinst() {
+	if [[ ${CHOST} == *-solaris* ]] ; then
+		einfo "Note: to use lsof on Solaris you need read permissions on"
+		einfo "/dev/kmem, i.e. you need to be root, or to be in the group sys"
+	elif [[ ${CHOST} == *-aix* ]] ; then
+		einfo "Note: to use lsof on AIX you need read permissions on /dev/mem and"
+		einfo "/dev/kmem, i.e. you need to be root, or to be in the group system"
+	fi
+}
-- 
cgit v1.2.3