From 7bc9c63c9da678a7e6fceb095d56c634afd22c56 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 15 Dec 2019 18:09:03 +0000
Subject: gentoo resync : 15.12.2019

---
 sys-power/cpupower/cpupower-5.4.ebuild | 67 ++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 sys-power/cpupower/cpupower-5.4.ebuild

(limited to 'sys-power/cpupower/cpupower-5.4.ebuild')

diff --git a/sys-power/cpupower/cpupower-5.4.ebuild b/sys-power/cpupower/cpupower-5.4.ebuild
new file mode 100644
index 000000000000..d45b53b560a1
--- /dev/null
+++ b/sys-power/cpupower/cpupower-5.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="Shows and sets processor power related values"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI="https://cdn.kernel.org/pub/linux/kernel/v${PV%%.*}.x/linux-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="nls"
+
+# File collision w/ headers of the deprecated cpufrequtils
+RDEPEND="sys-apps/pciutils
+	!<sys-apps/linux-misc-apps-3.6-r2
+	!sys-power/cpufrequtils"
+DEPEND="${RDEPEND}
+	virtual/os-headers
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}/cpupower-5.4-cflags.patch"
+)
+
+S="${WORKDIR}/linux-${PV}"
+
+src_configure() {
+	export bindir="${EPREFIX}/usr/bin"
+	export sbindir="${EPREFIX}/usr/sbin"
+	export mandir="${EPREFIX}/usr/share/man"
+	export includedir="${EPREFIX}/usr/include"
+	export libdir="${EPREFIX}/usr/$(get_libdir)"
+	export localedir="${EPREFIX}/usr/share/locale"
+	export docdir="${EPREFIX}/usr/share/doc/${PF}"
+	export confdir="${EPREFIX}/etc"
+	export V=1
+	export NLS=$(usex nls true false)
+}
+
+src_compile() {
+	myemakeargs=(
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		LD="$(tc-getCC)"
+		VERSION=${PV}
+	)
+
+	cd tools/power/cpupower || die
+	emake "${myemakeargs[@]}"
+}
+
+src_install() {
+	cd tools/power/cpupower || die
+	emake "${myemakeargs[@]}" DESTDIR="${D}" install
+	doheader lib/cpupower.h
+	einstalldocs
+
+	newconfd "${FILESDIR}"/conf.d-r2 cpupower
+	newinitd "${FILESDIR}"/init.d-r4 cpupower
+
+	systemd_dounit "${FILESDIR}"/cpupower-frequency-set.service
+	systemd_install_serviced "${FILESDIR}"/cpupower-frequency-set.service.conf
+}
-- 
cgit v1.2.3