From 6e356edde093fb3589ab7a5859685e85c2873ab0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 16 Sep 2022 17:15:17 +0100
Subject: gentoo auto-resync : 16:09:2022 - 17:15:17

---
 sys-libs/libcxxabi/Manifest                        |   2 +
 .../libcxxabi/libcxxabi-16.0.0_pre20220915.ebuild  | 128 +++++++++++++++++++++
 2 files changed, 130 insertions(+)
 create mode 100644 sys-libs/libcxxabi/libcxxabi-16.0.0_pre20220915.ebuild

(limited to 'sys-libs/libcxxabi')

diff --git a/sys-libs/libcxxabi/Manifest b/sys-libs/libcxxabi/Manifest
index a6f415d0062f..e7dc32cae72a 100644
--- a/sys-libs/libcxxabi/Manifest
+++ b/sys-libs/libcxxabi/Manifest
@@ -1,3 +1,4 @@
+DIST llvm-project-02a27b38909edc46c41732f79a837c95c9992d5a.tar.gz 167414990 BLAKE2B cd9c4be6d3155a4cbf1abff9d8246b9d6fea98e29459c226bda36df250cc22883f08175514fce037d146866d521a56669678b5c35b5163b38532b8c2920b25a6 SHA512 e862e148b8f053d8f4d40de8db9a4db587cb0c7b4120fe433d769aa2772a1aabd697c3c3f8ee34f547ee12c4bc4355116d5694d5f451264f8719d4af0fb32cb0
 DIST llvm-project-14.0.6.src.tar.xz 105618228 BLAKE2B ee67c5407df8cef493b9c0004f15e428f22a536a17e5f4e3eb29a003b8a8ec0abe0fa3e072591161d5f30ef7d8867c1ce34d1b341ad858e93c00263499941a99 SHA512 6fc6eeb60fac698702d1aac495fc0161eb7216a1f8db2020af8fccec5837831f7cc20dc2a169bf4f0b5f520748280b4a86621f3697d622aa58faaa45dbfaad13
 DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf0569c97b5ee4b1bd58eceb10e1879a30880c741c3d66bedd462c892309b688fb7b2673115a62d1f74d71ee375a578de9547f SHA512 b4a7b368532a7a4a24376cfa7db8f6d3478f6d4446474342fc00b474ecf466330cd0f16783209263c4c72d5fc7ddedfb11b95578842e700cfb7ee0bb34cc95d6
 DIST llvm-project-15.0.0.src.tar.xz 112062796 BLAKE2B 947917b6c75cbd8882133dc01f57013523274962371ac5ae4a22b010f8a7d5d31288c1d9847bf19ba919fa3110fe34a8ff937107fe19bd064ed87bf4d08d8a51 SHA512 e5aacbe7574dcec62017cc03c9fa2ee4cf075125a3d6c3975c38f06e91adcebb1ff92bcf40c6dd67db087813c60b15a04f1424c713d751199518b58025ce87fc
@@ -8,4 +9,5 @@ EBUILD libcxxabi-14.0.6.ebuild 3509 BLAKE2B e6fa29bba6fcc72fa1c049ba696fd9cb6b34
 EBUILD libcxxabi-15.0.0.9999.ebuild 3291 BLAKE2B 4b65300aaa146a9a864ae63fc829c0a0ca8e44f07a19a5b7bf3c13f26bc26340a81479f0f29483b7b1ecad810de7701d92fc247b34340e7d2d674dc554213f09 SHA512 cb6fdea8f3964ec39d350652ffa8a913758298eb22ccbe9a70f4ffd26f40b04747a13b88382c5dd64cc9a45541165b2df966bd2d3f3b0f9ec063e38e9640e052
 EBUILD libcxxabi-15.0.0.ebuild 3339 BLAKE2B 2fa9fdaefa07c7acb984c41365ad894150d30ecde568436bbe5cd5f55b1a2b25aad7a6880d4915979c5402e0252ba860b5fbe8d5aaa4ff276698c8530ede90be SHA512 0fe88d8e1ceb47885738f44b2fab2b9a737b2e0257ec5a0dffe359c5cf1921f9f0893f04f3e75c2715b74b12e63b7c20952d461f73768b5f3aef165de2e79b8b
 EBUILD libcxxabi-16.0.0.9999.ebuild 3291 BLAKE2B 4b65300aaa146a9a864ae63fc829c0a0ca8e44f07a19a5b7bf3c13f26bc26340a81479f0f29483b7b1ecad810de7701d92fc247b34340e7d2d674dc554213f09 SHA512 cb6fdea8f3964ec39d350652ffa8a913758298eb22ccbe9a70f4ffd26f40b04747a13b88382c5dd64cc9a45541165b2df966bd2d3f3b0f9ec063e38e9640e052
+EBUILD libcxxabi-16.0.0_pre20220915.ebuild 3291 BLAKE2B 4b65300aaa146a9a864ae63fc829c0a0ca8e44f07a19a5b7bf3c13f26bc26340a81479f0f29483b7b1ecad810de7701d92fc247b34340e7d2d674dc554213f09 SHA512 cb6fdea8f3964ec39d350652ffa8a913758298eb22ccbe9a70f4ffd26f40b04747a13b88382c5dd64cc9a45541165b2df966bd2d3f3b0f9ec063e38e9640e052
 MISC metadata.xml 557 BLAKE2B 4f6b0acb7cfdf74971a6fd96051d9f9020141c6117333a8de42bd043935b7bff8d9942faabdf3b1c94597c460393f64eb7d3f7b7d49f39ecfd0094de460f563e SHA512 67a812ef768e681ae77ef6e13bccffcbe53b41e94901f0558b3c7acaf896605ca670c4bb5a690bd9afa3b5a76271341710520a6abc0024c18f437fabde20e847
diff --git a/sys-libs/libcxxabi/libcxxabi-16.0.0_pre20220915.ebuild b/sys-libs/libcxxabi/libcxxabi-16.0.0_pre20220915.ebuild
new file mode 100644
index 000000000000..893a76363592
--- /dev/null
+++ b/sys-libs/libcxxabi/libcxxabi-16.0.0_pre20220915.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit cmake-multilib flag-o-matic llvm llvm.org python-any-r1 \
+	toolchain-funcs
+
+DESCRIPTION="Low level support for a standard C++ library"
+HOMEPAGE="https://libcxxabi.llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions || ( UoI-NCSA MIT )"
+SLOT="0"
+KEYWORDS=""
+IUSE="+clang static-libs test"
+REQUIRED_USE="test? ( clang )"
+RESTRICT="!test? ( test )"
+
+# in 15.x, cxxabi.h is moving from libcxx to libcxxabi
+RDEPEND+="
+	!<sys-libs/libcxx-15
+"
+# llvm-6 for new lit options
+DEPEND="
+	${RDEPEND}
+	>=sys-devel/llvm-6
+"
+BDEPEND="
+	clang? (
+		sys-devel/clang
+	)
+	!test? (
+		${PYTHON_DEPS}
+	)
+	test? (
+		$(python_gen_any_dep 'dev-python/lit[${PYTHON_USEDEP}]')
+	)
+"
+
+LLVM_COMPONENTS=( runtimes libcxx{abi,} llvm/cmake cmake )
+LLVM_TEST_COMPONENTS=( llvm/utils/llvm-lit )
+llvm.org_set_globals
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/lit[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	# darwin prefix builds do not have llvm installed yet, so rely on bootstrap-prefix
+	# to set the appropriate path vars to LLVM instead of using llvm_pkg_setup.
+	if [[ ${CHOST} != *-darwin* ]] || has_version dev-lang/llvm; then
+		llvm_pkg_setup
+	fi
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	if use clang && ! tc-is-clang; then
+		# Only do this conditionally to allow overriding with
+		# e.g. CC=clang-13 in case of breakage
+		local -x CC=${CHOST}-clang
+		local -x CXX=${CHOST}-clang++
+		strip-unsupported-flags
+	fi
+
+	# link against compiler-rt instead of libgcc if this is what clang does
+	local want_compiler_rt=OFF
+	if tc-is-clang; then
+		local compiler_rt=$($(tc-getCC) ${CFLAGS} ${CPPFLAGS} \
+			${LDFLAGS} -print-libgcc-file-name)
+		if [[ ${compiler_rt} == *libclang_rt* ]]; then
+			want_compiler_rt=ON
+		fi
+	fi
+
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		-DCMAKE_CXX_COMPILER_TARGET="${CHOST}"
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DLLVM_ENABLE_RUNTIMES="libcxxabi;libcxx"
+		-DLLVM_INCLUDE_TESTS=OFF
+		-DLLVM_LIBDIR_SUFFIX=${libdir#lib}
+		-DLIBCXXABI_ENABLE_SHARED=ON
+		-DLIBCXXABI_ENABLE_STATIC=$(usex static-libs)
+		-DLIBCXXABI_INCLUDE_TESTS=$(usex test)
+		-DLIBCXXABI_USE_COMPILER_RT=${want_compiler_rt}
+
+		# upstream is omitting standard search path for this
+		# probably because gcc & clang are bundling their own unwind.h
+		-DLIBCXXABI_LIBUNWIND_INCLUDES="${EPREFIX}"/usr/include
+
+		-DLIBCXX_LIBDIR_SUFFIX=
+		-DLIBCXX_ENABLE_SHARED=ON
+		-DLIBCXX_ENABLE_STATIC=OFF
+		-DLIBCXX_CXX_ABI=libcxxabi
+		-DLIBCXX_ENABLE_ABI_LINKER_SCRIPT=OFF
+		-DLIBCXX_HAS_MUSL_LIBC=$(usex elibc_musl)
+		-DLIBCXX_HAS_GCC_S_LIB=OFF
+		-DLIBCXX_INCLUDE_BENCHMARKS=OFF
+		-DLIBCXX_INCLUDE_TESTS=OFF
+	)
+	if use test; then
+		local clang_path=$(type -P "${CHOST:+${CHOST}-}clang" 2>/dev/null)
+		[[ -n ${clang_path} ]] || die "Unable to find ${CHOST}-clang for tests"
+
+		mycmakeargs+=(
+			-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+			-DLLVM_LIT_ARGS="$(get_lit_flags)"
+			-DPython3_EXECUTABLE="${PYTHON}"
+		)
+	fi
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_build cxxabi
+}
+
+multilib_src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-cxxabi
+}
+
+multilib_src_install() {
+	DESTDIR="${D}" cmake_build install-cxxabi
+}
-- 
cgit v1.2.3