From 407525b571b48cfd65e1ad7a02d250a927c967c9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 1 Dec 2017 03:04:39 +0000
Subject: gentoo resync : 01.12.2017

---
 sys-libs/libaal/libaal-1.0.7.ebuild | 42 +++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 sys-libs/libaal/libaal-1.0.7.ebuild

(limited to 'sys-libs/libaal/libaal-1.0.7.ebuild')

diff --git a/sys-libs/libaal/libaal-1.0.7.ebuild b/sys-libs/libaal/libaal-1.0.7.ebuild
new file mode 100644
index 000000000000..78fb9df4d93b
--- /dev/null
+++ b/sys-libs/libaal/libaal-1.0.7.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="library required by reiser4progs"
+HOMEPAGE="https://sourceforge.net/projects/reiser4/"
+SRC_URI="mirror://sourceforge/reiser4/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 -sparc ~x86"
+IUSE="static-libs"
+
+DEPEND="virtual/os-headers"
+
+src_prepare() {
+	default
+
+	# remove stupid CFLAG hardcodes
+	sed -i \
+		-e "/GENERIC_CFLAGS/s:-O3::" \
+		-e "/^CFLAGS=/s:\"\":\"${CFLAGS}\":" \
+		configure || die
+	printf '#!/bin/sh\n:\n' > run-ldconfig || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-libminimal
+		--enable-memory-manager
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	gen_usr_ldscript -a aal{,-minimal}
+}
-- 
cgit v1.2.3