From 032a3dbb5d4ea63ec6c2ceb39c067ea6424b5792 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 20 Jan 2020 19:28:42 +0000
Subject: gentoo resync : 20.01.2020

---
 sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild | 116 ++++++++++++++++++++++++++++
 1 file changed, 116 insertions(+)
 create mode 100644 sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild

(limited to 'sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild')

diff --git a/sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild b/sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild
new file mode 100644
index 000000000000..15912e502337
--- /dev/null
+++ b/sys-libs/gwenhywfar/gwenhywfar-5.1.2.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_rc/rc}"
+inherit qmake-utils
+
+DESCRIPTION="Multi-platform helper library for other libraries"
+HOMEPAGE="https://www.aquamaniac.de/sites/aqbanking/index.php"
+SRC_URI="https://www.aquamaniac.de/rdm/attachments/download/234/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/79" # correspond with libgwenhywfar.so version
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug designer doc fox gtk libressl qml qt5 sensors serialport test webkit"
+
+REQUIRED_USE="designer? ( qt5 ) qml? ( qt5 ) sensors? ( qt5 ) serialport? ( qt5 ) webkit? ( qt5 )"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+COMMON_DEPEND="
+	dev-libs/libgcrypt:0=
+	dev-libs/libgpg-error
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-libs/gnutls:=
+	virtual/libiconv
+	virtual/libintl
+	virtual/opengl
+	designer? ( dev-qt/designer:5 )
+	fox? ( x11-libs/fox:1.6 )
+	gtk? ( x11-libs/gtk+:3 )
+	qml? ( dev-qt/qtdeclarative:5 )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qthelp:5
+		dev-qt/qtmultimedia:5[widgets]
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtscript:5
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		dev-qt/qtxml:5
+		dev-qt/qtxmlpatterns:5
+	)
+	sensors? ( dev-qt/qtsensors:5 )
+	serialport? ( dev-qt/qtserialport:5 )
+	webkit? ( dev-qt/qtwebkit:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( !<app-office/gnucash-3.7[aqbanking] )
+"
+
+# broken upstream, reported but got no reply
+RESTRICT+=" test"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	disableQtModule() {
+		local module
+		for module in ${@}; do
+			sed -e "/qtHaveModule(${module})/s|^|#DONT|" -i configure || die
+		done
+	}
+
+	use designer || disableQtModule designer uitools
+	use qml || disableQtModule qml qmltest
+	use sensors || disableQtModule sensors
+	use serialport || disableQtModule serialport
+	use test || disableQtModule testlib
+	use webkit || disableQtModule webkit webkitwidgets
+
+	local guis=()
+	use fox && guis+=( fox16 )
+	use gtk && guis+=( gtk3 )
+	use qt5 && guis+=( qt5 )
+
+	local myeconfargs=(
+		--enable-ssl
+		--with-docpath="${EPREFIX}/usr/share/doc/${PF}/apidoc"
+		$(use_enable debug)
+		$(use_enable doc full-doc)
+	)
+	use qt5 && myeconfargs+=(
+		--with-qt5-moc="$(qt5_get_bindir)/moc"
+		--with-qt5-qmake="$(qt5_get_bindir)/qmake"
+	)
+
+	guis_config="--with-guis=${guis[@]}"
+	econf "${myeconfargs[@]}" "${guis_config}"
+}
+
+src_compile() {
+	emake
+	use doc && emake srcdoc
+}
+
+src_install() {
+	default
+	use doc && emake DESTDIR="${D}" install-srcdoc
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3