From 616579b5d773c50af31ee56f00105d96ce641ca2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Aug 2021 10:30:13 +0100
Subject: gentoo resync : 14.08.2021

---
 sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild | 71 +++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild

(limited to 'sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild')

diff --git a/sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild b/sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild
new file mode 100644
index 000000000000..be9165376fa7
--- /dev/null
+++ b/sys-kernel/pf-sources/pf-sources-5.13_p5.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Define what default functions to run
+ETYPE="sources"
+
+# No 'experimental' USE flag provided, but we still want to use genpatches
+K_EXP_GENPATCHES_NOUSE="1"
+
+# Just get basic genpatches, -pf patch set already includes vanilla-linux updates
+K_GENPATCHES_VER="1"
+
+# -pf already sets EXTRAVERSION to kernel Makefile
+K_NOSETEXTRAVERSION="1"
+
+# Not supported by the Gentoo security team
+K_SECURITY_UNSUPPORTED="1"
+
+# We want the very basic patches from gentoo-sources, experimental patch is
+# already included in pf-sources
+K_WANT_GENPATCHES="base extras"
+
+SHPV="${PV/_p*/}"
+
+inherit kernel-2 optfeature
+detect_version
+
+DESCRIPTION="Linux kernel fork that includes the pf-kernel patchset and Gentoo's genpatches"
+HOMEPAGE="https://gitlab.com/post-factum/pf-kernel/-/wikis/README
+	https://dev.gentoo.org/~mpagano/genpatches/"
+SRC_URI="${KERNEL_URI}
+	https://github.com/pfactum/pf-kernel/compare/v${SHPV}...v${SHPV}-pf${PV/*_p/}.diff -> ${P}.patch
+	https://dev.gentoo.org/~mpagano/genpatches/tarballs/genpatches-${SHPV}-${K_GENPATCHES_VER}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/genpatches/tarballs/genpatches-${SHPV}-${K_GENPATCHES_VER}.extras.tar.xz
+	https://gitlab.com/alfredchen/projectc/-/raw/master/${SHPV}/prjc_v${SHPV}-r2.patch
+	https://raw.githubusercontent.com/GKernelCI/linux-patches/5.12/5021_BMQ-and-PDS-gentoo-defaults-v5.12-r0.patch"
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+S="${WORKDIR}/linux-${PVR}-pf"
+
+PATCHES=( "${DISTDIR}/${P}.patch"
+	"${DISTDIR}/prjc_v${SHPV}-r2.patch"
+	"${DISTDIR}/5021_BMQ-and-PDS-gentoo-defaults-v5.12-r0.patch" )
+
+K_EXTRAEINFO="For more info on pf-sources and details on how to report problems,
+	see: ${HOMEPAGE}."
+
+pkg_setup() {
+	ewarn ""
+	ewarn "${PN} is *not* supported by the Gentoo Kernel Project in any way."
+	ewarn "If you need support, please contact the pf developers directly."
+	ewarn "Do *not* open bugs in Gentoo's bugzilla unless you have issues with"
+	ewarn "the ebuilds. Thank you."
+	ewarn ""
+
+	kernel-2_pkg_setup
+}
+
+src_prepare() {
+	# kernel-2_src_prepare doesn't apply PATCHES().
+	default
+}
+
+pkg_postinst() {
+	kernel-2_pkg_postinst
+
+	optfeature "userspace KSM helper" sys-process/uksmd
+}
-- 
cgit v1.2.3