From 9ec9cbf23e468492eab5e3a31836c699e8c5c534 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 4 Aug 2022 14:05:21 +0100
Subject: gentoo auto-resync : 04:08:2022 - 14:05:20

---
 sys-kernel/linux-headers/linux-headers-5.19.ebuild | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 sys-kernel/linux-headers/linux-headers-5.19.ebuild

(limited to 'sys-kernel/linux-headers/linux-headers-5.19.ebuild')

diff --git a/sys-kernel/linux-headers/linux-headers-5.19.ebuild b/sys-kernel/linux-headers/linux-headers-5.19.ebuild
new file mode 100644
index 000000000000..e9f071f1dbf2
--- /dev/null
+++ b/sys-kernel/linux-headers/linux-headers-5.19.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arc arm arm64 csky hexagon hppa ia64 loong m68k microblaze mips nios2 openrisc ppc ppc64 riscv s390 sh sparc x86 xtensa"
+inherit kernel-2
+detect_version
+
+PATCH_PV=${PV} # to ease testing new versions against not existing patches
+PATCH_VER="0"
+PATCH_DEV="xen0n"
+SRC_URI="${KERNEL_URI}
+	${PATCH_VER:+https://dev.gentoo.org/~${PATCH_DEV}/distfiles/sys-kernel/linux-headers/gentoo-headers-${PATCH_PV}-${PATCH_VER}.tar.xz}"
+S="${WORKDIR}/linux-${PV}"
+
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~loong"
+
+BDEPEND="app-arch/xz-utils
+	dev-lang/perl"
+
+# bug #816762
+RESTRICT="test"
+
+[[ -n ${PATCH_VER} ]] && PATCHES=( "${WORKDIR}"/${PATCH_PV} )
+
+src_unpack() {
+	# avoid kernel-2_src_unpack
+	default
+}
+
+src_prepare() {
+	# TODO: May need forward porting to newer versions
+	use elibc_musl && PATCHES+=(
+		"${FILESDIR}"/${PN}-5.10-Use-stddefs.h-instead-of-compiler.h.patch
+		"${FILESDIR}"/${PN}-5.15-remove-inclusion-sysinfo.h.patch
+	)
+
+	# avoid kernel-2_src_prepare
+	default
+}
+
+src_test() {
+	emake headers_check ${xmakeopts}
+}
+
+src_install() {
+	kernel-2_src_install
+
+	find "${ED}" \( -name '.install' -o -name '*.cmd' \) -delete || die
+	# delete empty directories
+	find "${ED}" -empty -type d -delete || die
+}
-- 
cgit v1.2.3