From 95f4ecedd41206e678e2ddec24f8382ba2287dd1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 31 Mar 2024 02:13:53 +0100
Subject: gentoo auto-resync : 31:03:2024 - 02:13:53

---
 sys-kernel/linux-docs/linux-docs-6.8.2.ebuild | 47 +++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 sys-kernel/linux-docs/linux-docs-6.8.2.ebuild

(limited to 'sys-kernel/linux-docs/linux-docs-6.8.2.ebuild')

diff --git a/sys-kernel/linux-docs/linux-docs-6.8.2.ebuild b/sys-kernel/linux-docs/linux-docs-6.8.2.ebuild
new file mode 100644
index 000000000000..15ca9ae39bce
--- /dev/null
+++ b/sys-kernel/linux-docs/linux-docs-6.8.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9,10,11} )
+inherit linux-info python-any-r1 toolchain-funcs
+
+MY_P=linux-${PV}
+
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Developer documentation generated from the Linux kernel"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI="https://www.kernel.org/pub/linux/kernel/v6.x/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+IUSE="graphviz"
+
+RDEPEND="graphviz? ( >=media-gfx/graphviz-5.0.0 )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-python/sphinx-7.2.3
+	dev-python/sphinx-rtd-theme
+	media-libs/fontconfig
+	$(python_gen_any_dep '
+		>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
+	')"
+
+src_prepare() {
+	default
+	# Fix the Python shebangs.
+	python_fix_shebang "${S}/Documentation/sphinx/"
+}
+
+src_compile() {
+	local ARCH="$(tc-arch-kernel)"
+	unset KBUILD_OUTPUT
+	HTML_DOCS=( Documentation/output/. )
+	emake htmldocs
+}
+
+src_install() {
+	einstalldocs
+}
-- 
cgit v1.2.3