From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 .../gentoo-kernel/gentoo-kernel-5.4.136.ebuild     | 97 ----------------------
 1 file changed, 97 deletions(-)
 delete mode 100644 sys-kernel/gentoo-kernel/gentoo-kernel-5.4.136.ebuild

(limited to 'sys-kernel/gentoo-kernel/gentoo-kernel-5.4.136.ebuild')

diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.136.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.136.ebuild
deleted file mode 100644
index 1bf22439675a..000000000000
--- a/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.136.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 2020-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit kernel-build
-
-MY_P=linux-${PV%.*}
-GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
-# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
-CONFIG_VER=5.4.21
-CONFIG_HASH=2809b7faa6a8cb232cd825096c146b7bdc1e08ea
-GENTOO_CONFIG_VER=5.4.114
-
-DESCRIPTION="Linux kernel built with Gentoo patches"
-HOMEPAGE="https://www.kernel.org/"
-SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
-	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
-	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
-	https://github.com/mgorny/gentoo-kernel-config/archive/v${GENTOO_CONFIG_VER}.tar.gz
-		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
-	amd64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-x86_64.config
-			-> kernel-x86_64.config.${CONFIG_VER}
-	)
-	arm64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-aarch64.config
-			-> kernel-aarch64.config.${CONFIG_VER}
-	)
-	ppc64? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-ppc64le.config
-			-> kernel-ppc64le.config.${CONFIG_VER}
-	)
-	x86? (
-		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-i686.config
-			-> kernel-i686.config.${CONFIG_VER}
-	)"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="debug"
-
-RDEPEND="
-	!sys-kernel/gentoo-kernel-bin:${SLOT}"
-BDEPEND="
-	debug? ( dev-util/pahole )"
-PDEPEND="
-	>=virtual/dist-kernel-${PV}"
-
-pkg_pretend() {
-	ewarn "Starting with 5.4.52, Distribution Kernels are switching from Arch"
-	ewarn "Linux configs to Fedora.  Please keep a backup kernel just in case."
-
-	kernel-install_pkg_pretend
-}
-
-src_prepare() {
-	local PATCHES=(
-		# meh, genpatches have no directory
-		"${WORKDIR}"/*.patch
-	)
-	default
-
-	# prepare the default config
-	case ${ARCH} in
-		amd64)
-			cp "${DISTDIR}/kernel-x86_64.config.${CONFIG_VER}" .config || die
-			;;
-		arm64)
-			cp "${DISTDIR}/kernel-aarch64.config.${CONFIG_VER}" .config || die
-			;;
-		ppc64)
-			cp "${DISTDIR}/kernel-ppc64le.config.${CONFIG_VER}" .config || die
-			;;
-		x86)
-			cp "${DISTDIR}/kernel-i686.config.${CONFIG_VER}" .config || die
-			;;
-		*)
-			die "Unsupported arch ${ARCH}"
-			;;
-	esac
-
-	echo 'CONFIG_LOCALVERSION="-gentoo-dist"' > "${T}"/version.config || die
-	local merge_configs=(
-		"${T}"/version.config
-		"${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"/base.config
-	)
-	use debug || merge_configs+=(
-		"${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"/no-debug.config
-	)
-	[[ ${ARCH} == x86 ]] && merge_configs+=(
-		"${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"/32-bit.config
-	)
-
-	kernel-build_merge_configs "${merge_configs[@]}"
-}
-- 
cgit v1.2.3