From 2f210c93c08515a806199783aabe37d12a0197cb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 30 May 2023 21:21:38 +0100
Subject: gentoo auto-resync : 30:05:2023 - 21:21:38

---
 sys-fs/vhba/vhba-20211218-r2.ebuild | 58 +++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 sys-fs/vhba/vhba-20211218-r2.ebuild

(limited to 'sys-fs/vhba/vhba-20211218-r2.ebuild')

diff --git a/sys-fs/vhba/vhba-20211218-r2.ebuild b/sys-fs/vhba/vhba-20211218-r2.ebuild
new file mode 100644
index 000000000000..62e5c2e3cf50
--- /dev/null
+++ b/sys-fs/vhba/vhba-20211218-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-mod-r1 udev
+
+MY_P=vhba-module-${PV}
+DESCRIPTION="Virtual (SCSI) Host Bus Adapter kernel module for the CDEmu suite"
+HOMEPAGE="https://cdemu.sourceforge.io/"
+SRC_URI="https://download.sourceforge.net/cdemu/vhba-module/${MY_P}.tar.xz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	virtual/udev
+"
+DEPEND="
+	${RDEPEND}
+"
+
+CONFIG_CHECK="~BLK_DEV_SR ~CHR_DEV_SG"
+
+src_compile() {
+	local modlist=( vhba )
+	local modargs=( KDIR="${KV_OUT_DIR}" )
+
+	linux-mod-r1_src_compile
+}
+
+src_prepare() {
+	default
+	# Avoid -Werror problems
+	sed -i -e '/ccflags/s/-Werror/-Wall/' Makefile || die "sed failed"
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	einfo "Generating udev rules ..."
+	udev_newrules - 69-vhba.rules <<-EOF
+		# do not edit this file, it will be overwritten on update
+		#
+		KERNEL=="vhba_ctl", SUBSYSTEM=="misc", TAG+="uaccess"
+	EOF
+}
+
+pkg_postinst() {
+	linux-mod-r1_pkg_postinst
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3