From 265dbe5dbc14c199299496c6db8fce3f76647015 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 21 Sep 2018 18:00:10 +0100
Subject: gentoo resync : 21.09.2018

---
 sys-fs/quota/quota-4.04-r2.ebuild | 82 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 sys-fs/quota/quota-4.04-r2.ebuild

(limited to 'sys-fs/quota/quota-4.04-r2.ebuild')

diff --git a/sys-fs/quota/quota-4.04-r2.ebuild b/sys-fs/quota/quota-4.04-r2.ebuild
new file mode 100644
index 000000000000..a6080157d8e6
--- /dev/null
+++ b/sys-fs/quota/quota-4.04-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="Linux quota tools"
+HOMEPAGE="https://sourceforge.net/projects/linuxquota/"
+SRC_URI="mirror://sourceforge/linuxquota/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ldap netlink nls rpc tcpd"
+
+RDEPEND="
+	ldap? ( >=net-nds/openldap-2.3.35 )
+	netlink? (
+		sys-apps/dbus
+		dev-libs/libnl:3
+	)
+	rpc? (
+		net-nds/rpcbind
+		elibc_glibc? ( sys-libs/glibc[-rpc(-)] )
+		net-libs/libtirpc
+		net-libs/rpcsvc-proto
+	)
+	tcpd? ( sys-apps/tcp-wrappers )
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-glibc226.patch"
+	"${FILESDIR}/${P}-Listen-on-a-TCP-socket.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--docdir="${EPREFIX%/}/usr/share/doc/${PF}"
+		$(use_enable nls)
+		$(use_enable ldap ldapmail)
+		$(use_enable netlink)
+		$(use_enable rpc)
+		$(use_enable rpc rpcsetquota)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc doc/* README.* Changelog
+
+	insinto /etc
+	insopts -m0644
+	doins warnquota.conf quotatab
+
+	newinitd "${FILESDIR}"/quota.rc7 quota
+	newconfd "${FILESDIR}"/quota.confd quota
+
+	if use rpc ; then
+		newinitd "${FILESDIR}"/rpc.rquotad.initd rpc.rquotad
+	fi
+
+	if use ldap ; then
+		insinto /etc/openldap/schema
+		insopts -m0644
+		doins "${FILESDIR}"/ldap-scripts/quota.schema
+
+		exeinto /usr/share/quota/ldap-scripts
+		doexe "${FILESDIR}"/ldap-scripts/*.pl
+		doexe "${FILESDIR}"/ldap-scripts/edquota_editor
+	fi
+}
-- 
cgit v1.2.3