From 145ac95c683ecda55a9b2cafc84dced2e9c29e03 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 24 Oct 2022 15:52:10 +0100
Subject: gentoo auto-resync : 24:10:2022 - 15:52:09

---
 sys-fs/mtools/mtools-4.0.42.ebuild | 53 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 sys-fs/mtools/mtools-4.0.42.ebuild

(limited to 'sys-fs/mtools/mtools-4.0.42.ebuild')

diff --git a/sys-fs/mtools/mtools-4.0.42.ebuild b/sys-fs/mtools/mtools-4.0.42.ebuild
new file mode 100644
index 000000000000..c123dc4b895b
--- /dev/null
+++ b/sys-fs/mtools/mtools-4.0.42.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="Utilities to access MS-DOS disks from Unix without mounting them"
+HOMEPAGE="https://www.gnu.org/software/mtools/ https://savannah.gnu.org/projects/mtools"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos ~x64-solaris"
+IUSE="gui"
+
+RDEPEND="
+	virtual/libiconv
+	gui? (
+		x11-libs/libICE
+		x11-libs/libXau
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXt
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	if ! use elibc_glibc && ! use elibc_musl ; then
+		# bug #447688
+		append-libs "-liconv"
+	fi
+
+	local myeconfargs=(
+		--sysconfdir="${EPREFIX}"/etc/mtools
+		$(use_with gui x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	local -a DOCS=( README* Release.notes )
+
+	default
+
+	insinto /etc/mtools
+	doins mtools.conf
+
+	# Default is fine
+	sed -i -e '/^SAMPLE FILE$/s:^:#:' "${ED}"/etc/mtools/mtools.conf || die
+}
-- 
cgit v1.2.3