From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 sys-fs/mergerfs/mergerfs-2.32.6.ebuild | 52 ++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 sys-fs/mergerfs/mergerfs-2.32.6.ebuild

(limited to 'sys-fs/mergerfs/mergerfs-2.32.6.ebuild')

diff --git a/sys-fs/mergerfs/mergerfs-2.32.6.ebuild b/sys-fs/mergerfs/mergerfs-2.32.6.ebuild
new file mode 100644
index 000000000000..2600359a9c80
--- /dev/null
+++ b/sys-fs/mergerfs/mergerfs-2.32.6.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A featureful union filesystem"
+HOMEPAGE="https://github.com/trapexit/mergerfs"
+
+SRC_URI="https://github.com/trapexit/mergerfs/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+# Vendorized libfuse that's bundled is under LGPL-2.1.
+LICENSE="ISC LGPL-2.1"
+SLOT="0"
+IUSE="+xattr"
+
+DEPEND="
+	xattr? ( sys-apps/attr )
+"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+	default
+
+	# Hand made build system at it's finest.
+	echo -e "#!/bin/sh\ntrue" >tools/update-version || die
+	echo "#pragma once" >src/version.hpp || die
+	echo "static const char MERGERFS_VERSION[] = \"${PV}\";" >>src/version.hpp || die
+
+	if ! use xattr; then
+		sed 's%USE_XATTR = 1%USE_XATTR = 0%g' -i Makefile || die
+	fi
+}
+
+src_compile() {
+	# https://bugs.gentoo.org/725978
+	tc-export AR CC CXX
+
+	default
+}
+
+src_install() {
+	dobin build/mergerfs
+	dosym mergerfs /usr/bin/mount.mergerfs
+	dodoc README.md
+	doman man/mergerfs.1
+}
-- 
cgit v1.2.3