From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 sys-fs/lde/lde-2.6.1-r2.ebuild | 54 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 sys-fs/lde/lde-2.6.1-r2.ebuild

(limited to 'sys-fs/lde/lde-2.6.1-r2.ebuild')

diff --git a/sys-fs/lde/lde-2.6.1-r2.ebuild b/sys-fs/lde/lde-2.6.1-r2.ebuild
new file mode 100644
index 000000000000..c0b1f4584101
--- /dev/null
+++ b/sys-fs/lde/lde-2.6.1-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="ext2fs and minix disk editor for linux"
+HOMEPAGE="http://lde.sourceforge.net/"
+SRC_URI="mirror://sourceforge/lde/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="sys-libs/ncurses:0="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-no-shadowing.patch"
+	"${FILESDIR}/${P}-fno-common.patch"
+	"${FILESDIR}/${P}-tinfo.patch"
+	"${FILESDIR}/${P}-respect-ar.patch"
+)
+
+DOCS=( WARNING README TODO COPYING )
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	# Remove prebuilt lde binary (so that failures to compile are fatal!)
+	# bug #776862
+	rm lde || die
+
+	cd macros || die
+	# bug #775968 again
+	touch ar-lib install-sh || die
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_install() {
+	dosbin "${PN}"
+	newman "doc/${PN}.man" "${PN}.8"
+	einstalldocs
+}
-- 
cgit v1.2.3