From 24fd814c326e282c4321965c31f341dad77e270d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 8 Jan 2021 11:28:34 +0000
Subject: gentoo resync : 08.01.2021

---
 .../android-file-transfer-linux-4.2.ebuild         | 80 ++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.2.ebuild

(limited to 'sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.2.ebuild')

diff --git a/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.2.ebuild b/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.2.ebuild
new file mode 100644
index 000000000000..0070b7afcbbb
--- /dev/null
+++ b/sys-fs/android-file-transfer-linux/android-file-transfer-linux-4.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit cmake python-single-r1 xdg
+
+DESCRIPTION="Android File Transfer for Linux"
+HOMEPAGE="https://github.com/whoozle/android-file-transfer-linux"
+
+if [[ "${PV}" = *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/whoozle/android-file-transfer-linux.git"
+else
+	SRC_URI="https://github.com/whoozle/android-file-transfer-linux/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="fuse libressl python qt5 taglib zune"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	sys-apps/file
+	sys-libs/readline:0=
+	fuse? ( sys-fs/fuse:0 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+	)
+	taglib? ( media-libs/taglib )
+	zune? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+# required to override src_prepare from xdg eclass
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FUSE="$(usex fuse)"
+		-DBUILD_MTPZ="$(usex zune)"
+		-DBUILD_PYTHON="$(usex python)"
+		-DBUILD_QT_UI="$(usex qt5)"
+		-DBUILD_SHARED_LIB="ON"
+		-DBUILD_TAGLIB="$(usex taglib)"
+		# Upstream recommends to keep this off as libusb is broken
+		-DUSB_BACKEND_LIBUSB="OFF"
+		$(usex qt5 '-DDESIRED_QT_VERSION=5' '')
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3