From 64e107b9b6058580ff0432107eb37cefb0b2a7d8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 22 Oct 2018 11:09:47 +0100
Subject: gentoo resync : 22.10.2018

---
 sys-devel/prelink/prelink-99999999.ebuild | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 sys-devel/prelink/prelink-99999999.ebuild

(limited to 'sys-devel/prelink/prelink-99999999.ebuild')

diff --git a/sys-devel/prelink/prelink-99999999.ebuild b/sys-devel/prelink/prelink-99999999.ebuild
new file mode 100644
index 000000000000..390d0c35e0cd
--- /dev/null
+++ b/sys-devel/prelink/prelink-99999999.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+MY_PN="${PN}-cross"
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools flag-o-matic git-r3
+
+DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
+HOMEPAGE="https://git.yoctoproject.org/cgit/cgit.cgi/prelink-cross/ https://people.redhat.com/jakub/prelink"
+EGIT_REPO_URI="https://git.yoctoproject.org/git/prelink-cross"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc selinux"
+
+DEPEND="selinux? ( sys-libs/libselinux[static-libs(+)] )
+	!dev-libs/libelf
+	sys-libs/binutils-libs
+	>=sys-libs/glibc-2.8"
+RDEPEND="${DEPEND}
+	>=sys-devel/binutils-2.18
+	>=dev-libs/elfutils-0.100[static-libs(+)]"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20130503-prelink-conf.patch
+	"${FILESDIR}"/${PN}-20130503-libiberty-md5.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
+
+	has_version 'dev-libs/elfutils[threads]' && append-ldflags -pthread
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable selinux)
+}
+
+src_install() {
+	default
+
+	use doc && dodoc doc/prelink.pdf
+
+	insinto /etc
+	doins doc/prelink.conf
+
+	exeinto /etc/cron.daily
+	newexe "${FILESDIR}"/prelink.cron prelink
+	newconfd "${FILESDIR}"/prelink.confd prelink
+}
+
+pkg_postinst() {
+	if [ -z "${REPLACING_VERSIONS}" ] ; then
+		elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
+		elog "found online at:"
+		elog "    https://wiki.gentoo.org/wiki/Prelink"
+		elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
+	fi
+}
-- 
cgit v1.2.3