From de49812990871e1705b64051c35161d5e6400269 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 24 Dec 2018 14:11:38 +0000
Subject: gentoo resync : 24.12.2018

---
 sys-block/parted/parted-3.2_p23.ebuild | 69 ++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 sys-block/parted/parted-3.2_p23.ebuild

(limited to 'sys-block/parted/parted-3.2_p23.ebuild')

diff --git a/sys-block/parted/parted-3.2_p23.ebuild b/sys-block/parted/parted-3.2_p23.ebuild
new file mode 100644
index 000000000000..b4a1e19a9f36
--- /dev/null
+++ b/sys-block/parted/parted-3.2_p23.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic
+
+DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
+HOMEPAGE="https://www.gnu.org/software/parted"
+SRC_URI="
+	mirror://gnu/${PN}/${P/_p*/}.tar.xz
+	mirror://debian/pool/main/p/${PN}/${PN}_${PV/_p/-}.debian.tar.xz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="+debug device-mapper nls readline selinux static-libs"
+RESTRICT="test"
+
+# specific version for gettext needed
+# to fix bug 85999
+RDEPEND="
+	>=sys-fs/e2fsprogs-1.27
+	device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+	readline? ( >=sys-libs/readline-5.2:0= >=sys-libs/ncurses-5.7-r7:0= )
+	selinux? ( sys-libs/libselinux )
+	elibc_uclibc? ( dev-libs/libiconv )
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( >=sys-devel/gettext-0.12.1-r2 )
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.2-devmapper.patch
+	"${FILESDIR}"/${PN}-3.2-po4a-mandir.patch
+)
+S=${WORKDIR}/${P/_p*/}
+
+src_prepare() {
+	default
+	sed -i -e '/atari\.patch/d' "${WORKDIR}"/debian/patches/series || die
+	for patch in $(< "${WORKDIR}"/debian/patches/series); do
+		eapply "${WORKDIR}/debian/patches/$patch"
+	done
+
+	eautoreconf
+}
+
+src_configure() {
+	use elibc_uclibc && append-libs -liconv
+	econf \
+		$(use_enable debug) \
+		$(use_enable device-mapper) \
+		$(use_enable nls) \
+		$(use_enable selinux) \
+		$(use_enable static-libs static) \
+		$(use_with readline) \
+		--disable-rpath \
+		--disable-silent-rules
+}
+
+DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API,FAT,USER.jp} )
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3