From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 sys-auth/seatd/seatd-0.5.0-r1.ebuild | 53 ++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 sys-auth/seatd/seatd-0.5.0-r1.ebuild

(limited to 'sys-auth/seatd/seatd-0.5.0-r1.ebuild')

diff --git a/sys-auth/seatd/seatd-0.5.0-r1.ebuild b/sys-auth/seatd/seatd-0.5.0-r1.ebuild
new file mode 100644
index 000000000000..4e1943599a35
--- /dev/null
+++ b/sys-auth/seatd/seatd-0.5.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson systemd
+
+DESCRIPTION="Minimal seat management daemon and universal library"
+HOMEPAGE="https://sr.ht/~kennylevinsen/seatd"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~kennylevinsen/seatd"
+else
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+	SRC_URI="https://git.sr.ht/~kennylevinsen/seatd/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+LICENSE="MIT"
+SLOT="0/1"
+IUSE="builtin elogind +server systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=">=app-text/scdoc-1.9.7"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		-Dwerror=false
+		$(meson_feature builtin)
+		$(meson_feature server)
+	)
+
+	if use elogind || use systemd; then
+		emesonargs+=( -Dlogind=enabled )
+	else
+		emesonargs+=( -Dlogind=disabled )
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use server; then
+		newinitd "${FILESDIR}/seatd.initd" seatd
+		systemd_dounit contrib/systemd/seatd.service
+	fi
+}
-- 
cgit v1.2.3