From e374e165c2ee372e9c6d10860ea6ef47f180f6b2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 2 Oct 2022 07:12:21 +0100
Subject: gentoo auto-resync : 02:10:2022 - 07:12:21

---
 sys-auth/pam_yubico/pam_yubico-2.27.ebuild | 48 ++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 sys-auth/pam_yubico/pam_yubico-2.27.ebuild

(limited to 'sys-auth/pam_yubico/pam_yubico-2.27.ebuild')

diff --git a/sys-auth/pam_yubico/pam_yubico-2.27.ebuild b/sys-auth/pam_yubico/pam_yubico-2.27.ebuild
new file mode 100644
index 000000000000..06d9db589c2b
--- /dev/null
+++ b/sys-auth/pam_yubico/pam_yubico-2.27.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools pam
+
+DESCRIPTION="Library for authenticating against PAM with a Yubikey"
+HOMEPAGE="https://github.com/Yubico/yubico-pam"
+SRC_URI="https://github.com/Yubico/yubico-pam/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ldap test"
+RESTRICT="!test? ( test )"
+S="${WORKDIR}/yubico-pam-${PV}"
+
+RDEPEND="
+	sys-libs/pam
+	sys-auth/libyubikey
+	>=sys-auth/ykclient-2.15
+	>=sys-auth/ykpers-1.6
+	ldap? ( net-nds/openldap:= )"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	test? ( dev-perl/Net-LDAP-Server )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	#challenge response could be optional but that seems horribly dangerous to me
+	local myeconfargs=(
+		--with-cr
+		--with-pam-dir="$(getpam_mod_dir)"
+		$(use_with ldap)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	dodoc doc/*
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3