From 2900e684ae4bdce1f20652587728095cd01a30a1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 25 Nov 2023 10:31:10 +0000
Subject: gentoo auto-resync : 25:11:2023 - 10:31:10

---
 sys-apps/usbutils/usbutils-017.ebuild | 66 +++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 sys-apps/usbutils/usbutils-017.ebuild

(limited to 'sys-apps/usbutils/usbutils-017.ebuild')

diff --git a/sys-apps/usbutils/usbutils-017.ebuild b/sys-apps/usbutils/usbutils-017.ebuild
new file mode 100644
index 000000000000..aff703996277
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-017.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+inherit python-single-r1
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="
+	https://www.kernel.org/pub/linux/utils/usb/usbutils/
+	https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/
+"
+SRC_URI="https://www.kernel.org/pub/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	virtual/libusb:1=
+	virtual/libudev:=
+"
+RDEPEND="
+	${DEPEND}
+	python? (
+		${PYTHON_DEPS}
+		sys-apps/hwdata
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	use python && python_fix_shebang lsusb.py.in
+}
+
+src_configure() {
+	local myeconfargs=(
+		--cache-file="${S}"/config.cache
+		--datarootdir="${EPREFIX}/usr/share"
+		--datadir="${EPREFIX}/usr/share/hwdata"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+	dobin usbreset # noinst_PROGRAMS, but installed by other distros
+
+	if ! use python ; then
+		rm -f "${ED}"/usr/bin/lsusb.py || die
+	fi
+}
-- 
cgit v1.2.3