From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 sys-apps/usbutils/usbutils-014.ebuild | 56 +++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sys-apps/usbutils/usbutils-014.ebuild

(limited to 'sys-apps/usbutils/usbutils-014.ebuild')

diff --git a/sys-apps/usbutils/usbutils-014.ebuild b/sys-apps/usbutils/usbutils-014.ebuild
new file mode 100644
index 000000000000..14581fea76a9
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-014.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="https://www.kernel.org/pub/linux/utils/usb/usbutils/
+	https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="virtual/libusb:1=
+	virtual/libudev:="
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )"
+RDEPEND="${DEPEND}
+	sys-apps/hwids
+	python? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+	use python && python_fix_shebang lsusb.py.in
+}
+
+src_configure() {
+	local myeconfargs=(
+		--datarootdir="${EPREFIX}/usr/share"
+		--datadir="${EPREFIX}/usr/share/misc"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+	dobin usbreset # noinst_PROGRAMS, but installed by other distros
+
+	if ! use python ; then
+		rm -f "${ED}"/usr/bin/lsusb.py || die
+	fi
+}
-- 
cgit v1.2.3