From abaa75b10f899ada8dd05b23cc03205064394bc6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 22 Jan 2021 20:28:19 +0000
Subject: gentoo resync : 22.01.2021

---
 sys-apps/usbguard/usbguard-1.0.0.ebuild | 80 +++++++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 sys-apps/usbguard/usbguard-1.0.0.ebuild

(limited to 'sys-apps/usbguard/usbguard-1.0.0.ebuild')

diff --git a/sys-apps/usbguard/usbguard-1.0.0.ebuild b/sys-apps/usbguard/usbguard-1.0.0.ebuild
new file mode 100644
index 000000000000..761a616c07c0
--- /dev/null
+++ b/sys-apps/usbguard/usbguard-1.0.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Daemon protecting your computer against BadUSB"
+HOMEPAGE="https://github.com/USBGuard/usbguard"
+SRC_URI="https://github.com/USBGuard/usbguard/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0/1"  # due to libusbguard.so.<1>.0.0
+KEYWORDS="~amd64 ~x86"
+IUSE="bash-completion dbus ldap policykit static-libs systemd"
+
+REQUIRED_USE="policykit? ( dbus )"
+
+CDEPEND="
+	dev-libs/pegtl
+	>=dev-libs/libsodium-0.4.5:=
+	>=dev-libs/protobuf-2.5.0:=
+	>=sys-cluster/libqb-0.16.0:=
+	sys-devel/gcc:*[cxx]
+	>=sys-libs/libcap-ng-0.7.0
+	>=sys-libs/libseccomp-2.0.0
+	>=sys-process/audit-2.7.7
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	dbus? (
+		dev-libs/glib:2
+		sys-apps/dbus
+		policykit? ( sys-auth/polkit[introspection] )
+	)
+	ldap? ( net-nds/openldap )
+	systemd? ( sys-apps/systemd )
+	"
+RDEPEND="${CDEPEND}
+	virtual/udev
+	"
+DEPEND="${CDEPEND}
+	app-text/asciidoc
+	dev-cpp/catch:1
+	dbus? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+		dev-util/gdbus-codegen
+	)
+	"
+
+src_configure() {
+	local myargs=(
+		$(use_with dbus)
+		$(use_with ldap)
+		$(use_with policykit polkit)
+		$(use_enable static-libs static)
+		$(use_enable systemd)
+	)
+
+	econf "${myargs[@]}"
+}
+
+src_install() {
+	default
+
+	keepdir /var/lib/log/usbguard
+
+	newinitd "${FILESDIR}"/${PN}-0.7.6-usbguard.openrc usbguard
+	use dbus && newinitd "${FILESDIR}"/${PN}-0.7.6-usbguard-dbus.openrc usbguard-dbus
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn 'BEFORE STARTING USBGUARD please be sure to create/generate'
+	ewarn '                         a rules file at /etc/usbguard/rules.conf'
+	ewarn '                         so that you do not'
+	ewarn '                                            GET LOCKED OUT'
+	ewarn "                         of this system (\"$(hostname)\")."
+	ewarn
+	ewarn 'This command may be of help:'
+	ewarn '  sudo sh -c "usbguard generate-policy > /etc/usbguard/rules.conf"'
+	ewarn
+}
-- 
cgit v1.2.3