From 85ba3f2cfe9ff2b952efb1f3c3c08840f8093246 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 7 Nov 2022 09:21:27 +0000
Subject: gentoo auto-resync : 07:11:2022 - 09:21:27

---
 sys-apps/sed/sed-4.9.ebuild | 56 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sys-apps/sed/sed-4.9.ebuild

(limited to 'sys-apps/sed/sed-4.9.ebuild')

diff --git a/sys-apps/sed/sed-4.9.ebuild b/sys-apps/sed/sed-4.9.ebuild
new file mode 100644
index 000000000000..1c4032498092
--- /dev/null
+++ b/sys-apps/sed/sed-4.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/sed.asc
+inherit flag-o-matic verify-sig
+
+DESCRIPTION="Super-useful stream editor"
+HOMEPAGE="http://sed.sourceforge.net/"
+SRC_URI="mirror://gnu/sed/${P}.tar.xz"
+SRC_URI+=" verify-sig? ( mirror://gnu/sed/${P}.tar.xz.sig )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="acl nls selinux static"
+
+RDEPEND="
+	!static? (
+		acl? ( virtual/acl )
+		nls? ( virtual/libintl )
+		selinux? ( sys-libs/libselinux )
+	)
+"
+DEPEND="${RDEPEND}
+	static? (
+		acl? ( virtual/acl[static-libs(+)] )
+		nls? ( virtual/libintl[static-libs(+)] )
+		selinux? ( sys-libs/libselinux[static-libs(+)] )
+	)
+"
+BDEPEND="nls? ( sys-devel/gettext )
+	verify-sig? ( sec-keys/openpgp-keys-sed )"
+
+src_configure() {
+	use static && append-ldflags -static
+
+	local myconf=(
+		--exec-prefix="${EPREFIX}"
+		$(use_enable acl)
+		$(use_enable nls)
+		$(use_with selinux)
+		# rename to gsed for better BSD compatibility
+		--program-prefix=g
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	# symlink to the standard name
+	dosym gsed /bin/sed
+	dosym gsed.1 /usr/share/man/man1/sed.1
+}
-- 
cgit v1.2.3