From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 sys-apps/pcmciautils/pcmciautils-018_p8.ebuild | 72 ++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 sys-apps/pcmciautils/pcmciautils-018_p8.ebuild

(limited to 'sys-apps/pcmciautils/pcmciautils-018_p8.ebuild')

diff --git a/sys-apps/pcmciautils/pcmciautils-018_p8.ebuild b/sys-apps/pcmciautils/pcmciautils-018_p8.ebuild
new file mode 100644
index 000000000000..ccfdd306b052
--- /dev/null
+++ b/sys-apps/pcmciautils/pcmciautils-018_p8.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=4
+inherit eutils flag-o-matic linux-info toolchain-funcs udev
+
+DEB_REV=${PV#*_p}
+MY_PV=${PV%_p*}
+
+DESCRIPTION="PCMCIA userspace utilities for Linux"
+HOMEPAGE="https://packages.qa.debian.org/pcmciautils"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PV}.orig.tar.gz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PV}-${DEB_REV}.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm ppc sh x86"
+IUSE="debug staticsocket"
+
+RDEPEND="virtual/modutils"
+DEPEND="${RDEPEND}
+	virtual/yacc
+	sys-devel/flex"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+pkg_setup() {
+	CONFIG_CHECK="~PCMCIA"
+	linux-info_pkg_setup
+
+	kernel_is lt 2 6 32 && ewarn "${P} requires at least kernel 2.6.32."
+
+	mypcmciaopts=(
+		STARTUP=$(usex staticsocket true false)
+		exec_prefix=/usr
+		UDEV=true
+		DEBUG=false
+		STATIC=false
+		V=true
+		udevdir="$(get_udevdir)"
+		CC="$(tc-getCC)"
+		LD="$(tc-getCC)"
+		AR="$(tc-getAR)"
+		STRIP=true
+		RANLIB="$(tc-getRANLIB)"
+		OPTIMIZATION="${CFLAGS} ${CPPFLAGS}"
+		DESTDIR="${D}"
+		)
+
+	use debug && append-cppflags -DDEBUG
+}
+
+src_prepare() {
+	epatch \
+		"${WORKDIR}"/debian/patches/no-modprobe-rules.patch \
+		"${WORKDIR}"/debian/patches/remove-libsysfs-dep.patch
+
+	sed -i \
+		-e '/CFLAGS/s:-fomit-frame-pointer::' \
+		-e '/dir/s:sbin:bin:g' \
+		Makefile || die
+}
+
+src_compile() {
+	emake "${mypcmciaopts[@]}"
+}
+
+src_install() {
+	emake "${mypcmciaopts[@]}" install
+
+	dodoc doc/*.txt
+}
-- 
cgit v1.2.3