From 64e107b9b6058580ff0432107eb37cefb0b2a7d8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 22 Oct 2018 11:09:47 +0100
Subject: gentoo resync : 22.10.2018

---
 sys-apps/openrc/Manifest             |   4 +-
 sys-apps/openrc/openrc-0.38.2.ebuild |   2 +-
 sys-apps/openrc/openrc-0.38.3.ebuild | 326 +++++++++++++++++++++++++++++++++++
 3 files changed, 330 insertions(+), 2 deletions(-)
 create mode 100644 sys-apps/openrc/openrc-0.38.3.ebuild

(limited to 'sys-apps/openrc')

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 139732269328..a01ac97e0197 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -6,10 +6,12 @@ DIST openrc-0.35.5.tar.gz 241784 BLAKE2B 6f63dcf30c430949f25108b0ca808f2317b2e58
 DIST openrc-0.36.tar.gz 240179 BLAKE2B 1361d22782d6063e7fce61a98ef1e1f754d0208ec58de02ae60a0950531d248ac6e65e1ed45b412c89288103f6848b24aa51dd66232aa46e7900b339cac21a57 SHA512 f4730489e595a9ac4477c2b410e034b4eea2b8111c12c2695916aa04102020f8c84cb24220d3aa552709898035aa196e2fd48cba9b12a71dff1f5c2b03c3d424
 DIST openrc-0.37.tar.gz 240928 BLAKE2B b802260a3bd71e6d8e6d54b21007024481d42a4f179eff824a39fb91f5b1cd4f7a2fd52d9e7f23b1077965b57d319a99a5b39b8cd2d7f66dfe272b4497d53a22 SHA512 16235774ad28a66308dd1ea00238b4025a4d26c9c0bb6cdb032f28d00479520c4c5fdb349f82d33a535eee3d491d0349b5871b15cae30ef296ec476883965b83
 DIST openrc-0.38.2.tar.gz 240924 BLAKE2B a50e567aa3ac1edfd4e7cbdfbf3d7ce6ac39b7d7c2b4a9bcc8cf088735fa436a334eb077ecb10b67f6f5faab979ba62729aca4f3f61e12167cbd48fc8a7f3776 SHA512 5c5f1cfa9990970a02619c5b97c0d424d921fe16e83767372beee9a7b296c6ea33b43ae4045cf7266254b98871a5d347de1040443fe8fc68d7b9d164eed909e6
+DIST openrc-0.38.3.tar.gz 238031 BLAKE2B 87d1546e21d581feda4064cd64bf43f762203becdcc4b002bf868f17403bd42770cb1106a8bc383c8d69e19ad66ad2bedaa7090c95206597e8a9b6e2ba481dcc SHA512 6bb42ccdab5fb24b11f5042bf19850f440d3494b6bd1d7b8db31b592f051fcd26feac1c8d9ef515238c53c6f5bf98a8c367a48471c178ae829e05c56bd24cfde
 EBUILD openrc-0.34.11.ebuild 10093 BLAKE2B 4f1e8fd970cc608d56df44eefe714390bf68ed18f499ee305f9e5908703f5b36228932e2b7384301021af330ac2ae5455f5b07cbcd6d5da475c042386b31fd9e SHA512 99ddc25723791ca82cd80c55790da6738b796d9fdd61c804821e3e26e4c8be5d9eeac56a9c689977008ce01f56b49319f0b5f65a5d7a08b318c9f38040553928
 EBUILD openrc-0.35.5.ebuild 9976 BLAKE2B e3c47e0f95115e34d7b9084ba2985b854de17030c11301a8ea1b8f6d89a28a2222665737ed2eb8c5f84a282b9d1587bd98ece6965700ca9d85c89815e7a862e6 SHA512 a78575665626eb2c56870429f84eddfae6ceee4ff26fcdaf525584989a538a40266b3dd741d444301b021b615fd401713fca8a24735a126c0a5ca98932bc57f0
 EBUILD openrc-0.36.ebuild 9848 BLAKE2B 8add10cb57cdee0f2b7a18f99279203ab996286eb335a1c162bd675d21962003faf143b65933bf6620c836345b536b4840d0e4088ef633fb78f5ae54e7d55526 SHA512 2cce39876ef342b136d9a85cbb8dfb10b3619c70175e18dc60c1bc8614d866669bd6cfb5e9ecb43643612d0bb8ae225c32b25318d528c82716137ec6965eeacd
 EBUILD openrc-0.37.ebuild 9848 BLAKE2B 8add10cb57cdee0f2b7a18f99279203ab996286eb335a1c162bd675d21962003faf143b65933bf6620c836345b536b4840d0e4088ef633fb78f5ae54e7d55526 SHA512 2cce39876ef342b136d9a85cbb8dfb10b3619c70175e18dc60c1bc8614d866669bd6cfb5e9ecb43643612d0bb8ae225c32b25318d528c82716137ec6965eeacd
-EBUILD openrc-0.38.2.ebuild 9837 BLAKE2B f089ebcc4c20bd528cffaa50aa4db2ac99b82efa2c449ec7ba9f88ca09bbc515d5df5637d639cd4650497e277057d6cb9078a6c7a417c9b2d9eb7ec59aa48e7d SHA512 9658b8f880105ce6cff9c11d40ba2526bdec9089dbfafcf5214e6660855f28b344da042d4411b9c1b2940b2fa00197d1a173fd75280ebf17d10201cbd01a0417
+EBUILD openrc-0.38.2.ebuild 9836 BLAKE2B 2538028c1766036d79089965a9402c3fa7a65178aa42d68caa22ae2e1c8962bddb21663867d5f0a245fe274227bf9d9dde925ef385fec9060c5f8bd5e0804585 SHA512 0145fab466fcc7f0d5ec48bae7b7a42b5967215e04c3896a5b4f47735994af966ad99ef19de9b5c8ce33037d851a6edc195ea5466ae2e2a8ec3243c6d292fda2
+EBUILD openrc-0.38.3.ebuild 9836 BLAKE2B 2538028c1766036d79089965a9402c3fa7a65178aa42d68caa22ae2e1c8962bddb21663867d5f0a245fe274227bf9d9dde925ef385fec9060c5f8bd5e0804585 SHA512 0145fab466fcc7f0d5ec48bae7b7a42b5967215e04c3896a5b4f47735994af966ad99ef19de9b5c8ce33037d851a6edc195ea5466ae2e2a8ec3243c6d292fda2
 EBUILD openrc-9999.ebuild 9848 BLAKE2B 8add10cb57cdee0f2b7a18f99279203ab996286eb335a1c162bd675d21962003faf143b65933bf6620c836345b536b4840d0e4088ef633fb78f5ae54e7d55526 SHA512 2cce39876ef342b136d9a85cbb8dfb10b3619c70175e18dc60c1bc8614d866669bd6cfb5e9ecb43643612d0bb8ae225c32b25318d528c82716137ec6965eeacd
 MISC metadata.xml 497 BLAKE2B a65de1314b8d3c0a01bde15654be667a5a59d4e569e2516fa17496143cf232e3f05ca43e48c7f0c4cdff5c610edaded48039888a6e67ccb7b0cb0a811b253541 SHA512 c93291d7caeb45ad2aaebc778795d65fe20666ef125c2382dd07c0d71aace5380f5cc5dd5eb1e3a80b883084f1c91d3635540d5d0451a030ae5649ba74de10fb
diff --git a/sys-apps/openrc/openrc-0.38.2.ebuild b/sys-apps/openrc/openrc-0.38.2.ebuild
index 86ce817e9122..bbca849aa190 100644
--- a/sys-apps/openrc/openrc-0.38.2.ebuild
+++ b/sys-apps/openrc/openrc-0.38.2.ebuild
@@ -13,7 +13,7 @@ if [[ ${PV} == "9999" ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd"
+	KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd"
 fi
 
 LICENSE="BSD-2"
diff --git a/sys-apps/openrc/openrc-0.38.3.ebuild b/sys-apps/openrc/openrc-0.38.3.ebuild
new file mode 100644
index 000000000000..bbca849aa190
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.38.3.ebuild
@@ -0,0 +1,326 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit debug ncurses pam newnet prefix +netifrc selinux static-libs
+	unicode kernel_linux kernel_FreeBSD"
+
+COMMON_DEPEND="kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-ubin-9.0_rc sys-process/fuser-bsd ) )
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? (
+		sys-auth/pambase
+		virtual/pam
+	)
+	audit? ( sys-process/audit )
+	kernel_linux? (
+		sys-process/psmisc
+		!<sys-process/procps-3.3.9-r2
+	)
+	selinux? (
+		sys-apps/policycoreutils
+		>=sys-libs/libselinux-2.6
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	!prefix? (
+		kernel_linux? (
+			>=sys-apps/sysvinit-2.86-r6[selinux?]
+			virtual/tmpfiles
+		)
+		kernel_FreeBSD? ( sys-freebsd/freebsd-sbin )
+	)
+	selinux? (
+		>=sec-policy/selinux-base-policy-2.20170204-r4
+		>=sec-policy/selinux-openrc-2.20170204-r4
+	)
+	!<app-shells/gentoo-bashcomp-20180302
+	!<app-shells/gentoo-zsh-completions-20180228
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_prepare() {
+	default
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/gitver.mk || die
+	fi
+}
+
+src_compile() {
+	unset LIBDIR #266688
+
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBNAME=$(get_libdir)
+		LIBEXECDIR=${EPREFIX}/lib/rc
+		MKBASHCOMP=yes
+		MKNET=$(usex newnet)
+		MKSELINUX=$(usex selinux)
+		MKAUDIT=$(usex audit)
+		MKPAM=$(usev pam)
+		MKSTATICLIBS=$(usex static-libs)
+		MKZSHCOMP=yes"
+
+	local brand="Unknown"
+	if use kernel_linux ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=Linux"
+		brand="Linux"
+	elif use kernel_FreeBSD ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=FreeBSD"
+		brand="FreeBSD"
+	fi
+	export BRANDING="Gentoo ${brand}"
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+	export DEBUG=$(usev debug)
+	export MKTERMCAP=$(usev ncurses)
+
+	tc-export CC AR RANLIB
+	emake ${MAKE_ARGS}
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+
+	# move the shared libs back to /usr so ldscript can install
+	# more of a minimal set of files
+	# disabled for now due to #270646
+	#mv "${ED}"/$(get_libdir)/lib{einfo,rc}* "${ED}"/usr/$(get_libdir)/ || die
+	#gen_usr_ldscript -a einfo rc
+	gen_usr_ldscript libeinfo.so
+	gen_usr_ldscript librc.so
+
+	if ! use kernel_linux; then
+		keepdir /lib/rc/init.d
+	fi
+	keepdir /lib/rc/tmp
+
+	# Backup our default runlevels
+	dodir /usr/share/"${PN}"
+	cp -PR "${ED}"/etc/runlevels "${ED}"/usr/share/${PN} || die
+	rm -rf "${ED}"/etc/runlevels
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/usr/share/openrc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	# install gentoo pam.d files
+	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+	newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+
+	# install documentation
+	dodoc ChangeLog *.md
+	if use newnet; then
+		dodoc README.newnet
+	fi
+}
+
+add_boot_init() {
+	local initd=$1
+	local runlevel=${2:-boot}
+	# if the initscript is not going to be installed and is not
+	# currently installed, return
+	[[ -e "${ED}"/etc/init.d/${initd} || -e "${EROOT}"etc/init.d/${initd} ]] \
+		|| return
+	[[ -e "${EROOT}"etc/runlevels/${runlevel}/${initd} ]] && return
+
+	# if runlevels dont exist just yet, then create it but still flag
+	# to pkg_postinst that it needs real setup #277323
+	if [[ ! -d "${EROOT}"etc/runlevels/${runlevel} ]] ; then
+		mkdir -p "${EROOT}"etc/runlevels/${runlevel}
+		touch "${EROOT}"etc/runlevels/.add_boot_init.created
+	fi
+
+	elog "Auto-adding '${initd}' service to your ${runlevel} runlevel"
+	ln -snf /etc/init.d/${initd} "${EROOT}"etc/runlevels/${runlevel}/${initd}
+}
+add_boot_init_mit_config() {
+	local config=$1 initd=$2
+	if [[ -e ${EROOT}${config} ]] ; then
+		if [[ -n $(sed -e 's:#.*::' -e '/^[[:space:]]*$/d' "${EROOT}"${config}) ]] ; then
+			add_boot_init ${initd}
+		fi
+	fi
+}
+
+pkg_preinst() {
+	local f LIBDIR=$(get_libdir)
+
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+
+	# termencoding was added in 0.2.1 and needed in boot
+	has_version ">=sys-apps/openrc-0.2.1" || add_boot_init termencoding
+
+	# swapfiles was added in 0.9.9 and needed in boot (february 2012)
+	has_version ">=sys-apps/openrc-0.9.9" || add_boot_init swapfiles
+
+	if ! has_version ">=sys-apps/openrc-0.11"; then
+		add_boot_init sysfs sysinit
+	fi
+
+	if ! has_version ">=sys-apps/openrc-0.11.3" ; then
+		migrate_udev_mount_script
+	fi
+
+	# these were added in 0.12.
+	if ! has_version ">=sys-apps/openrc-0.12"; then
+		add_boot_init loopback
+
+		# ensure existing /etc/conf.d/net is not removed
+		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
+		# this needs to stay in openrc ebuilds for a long time. :(
+		# Added in 0.12.
+		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
+			einfo "Modifying conf.d/net to keep it from being removed"
+			cat <<-EOF >>"${EROOT}"etc/conf.d/net
+
+# The network scripts are now part of net-misc/netifrc
+# In order to avoid sys-apps/${P} from removing this file, this comment was
+# added; you can safely remove this comment.  Please see
+# /usr/share/doc/netifrc*/README* for more information.
+EOF
+		fi
+	fi
+	has_version ">=sys-apps/openrc-0.14" || add_boot_init binfmt
+
+	if ! has_version ">=sys-apps/openrc-0.18.3"; then
+		add_boot_init mtab
+		if [[ -f "${EROOT}"etc/mtab ]] && [[ ! -L "${EROOT}"etc/mtab ]]; then
+			ewarn "${EROOT}etc/mtab will be replaced with a"
+			ewarn "symbolic link to /proc/self/mounts on the next"
+			ewarn "reboot."
+			ewarn "Change the setting in ${EROOT}etc/conf.d/mtab"
+			ewarn "if you do not want this to happen."
+		fi
+	fi
+
+	has_version ">=sys-apps/openrc-0.35" || add_boot_init cgroups sysinit
+
+}
+
+# >=OpenRC-0.11.3 requires udev-mount to be in the sysinit runlevel with udev.
+migrate_udev_mount_script() {
+	if [ -e "${EROOT}"etc/runlevels/sysinit/udev -a \
+		! -e "${EROOT}"etc/runlevels/sysinit/udev-mount ]; then
+		add_boot_init udev-mount sysinit
+	fi
+	return 0
+}
+
+pkg_postinst() {
+	local LIBDIR=$(get_libdir)
+
+	# Make our runlevels if they don't exist
+	if [[ ! -e "${EROOT}"etc/runlevels ]] || [[ -e "${EROOT}"etc/runlevels/.add_boot_init.created ]] ; then
+		einfo "Copying across default runlevels"
+		cp -RPp "${EROOT}"usr/share/${PN}/runlevels "${EROOT}"etc
+		rm -f "${EROOT}"etc/runlevels/.add_boot_init.created
+	else
+		if [[ ! -e "${EROOT}"etc/runlevels/sysinit/devfs ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/sysinit
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/sysinit/* \
+				"${EROOT}"etc/runlevels/sysinit
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/shutdown/mount-ro ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/shutdown
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/shutdown/* \
+				"${EROOT}"etc/runlevels/shutdown
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/nonetwork/local ]]; then
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/nonetwork \
+				"${EROOT}"etc/runlevels
+		fi
+	fi
+
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Added for 0.35.
+	if use kernel_linux && [[ ! -h "${EROOT}"/lib ]]; then
+		if [[ -d "${EROOT}$(get_libdir)"/rc ]]; then
+			cp -RPp "${EROOT}$(get_libdir)/rc" "${EROOT}"lib
+		fi
+	elif ! use kernel_linux; then
+		if [[ -d "${EROOT}$(get_libdir)"/rc ]]; then
+			cp -RPp "${EROOT}$(get_libdir)/rc" "${EROOT}"lib
+		fi
+	fi
+
+	# update the dependency tree after touching all files #224171
+	[[ "${EROOT}" = "/" ]] && "${EROOT}"/lib/rc/bin/rc-depend -u
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
+		ewarn "net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+}
-- 
cgit v1.2.3