From 7bc9c63c9da678a7e6fceb095d56c634afd22c56 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 15 Dec 2019 18:09:03 +0000
Subject: gentoo resync : 15.12.2019

---
 sys-apps/mcstrans/mcstrans-3.0.ebuild | 54 +++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 sys-apps/mcstrans/mcstrans-3.0.ebuild

(limited to 'sys-apps/mcstrans/mcstrans-3.0.ebuild')

diff --git a/sys-apps/mcstrans/mcstrans-3.0.ebuild b/sys-apps/mcstrans/mcstrans-3.0.ebuild
new file mode 100644
index 000000000000..e68d520f4372
--- /dev/null
+++ b/sys-apps/mcstrans/mcstrans-3.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit toolchain-funcs
+
+MY_RELEASEDATE="20191204"
+
+MY_P="${P//_/-}"
+IUSE=""
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/SELinuxProject/selinux.git"
+	S="${WORKDIR}/${MY_P}/${PN}"
+else
+	SRC_URI="https://github.com/SELinuxProject/selinux/releases/download/${MY_RELEASEDATE}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="SELinux context translation to human readable names"
+HOMEPAGE="https://github.com/SELinuxProject/selinux/wiki"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+DEPEND=">=sys-libs/libsepol-${PV}:=
+	>=sys-libs/libselinux-${PV}:=
+	dev-libs/libpcre:=
+	>=sys-libs/libcap-1.10-r10:="
+
+RDEPEND="${DEPEND}
+	!<sys-apps/policycoreutils-2.7_pre"
+
+src_prepare() {
+	default
+
+	sed -i 's/-Werror//g' "${S}"/*/Makefile || die "Failed to remove Werror"
+}
+
+src_compile() {
+	tc-export CC
+	default
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rf "${D}/etc/rc.d" || die
+
+	newinitd "${FILESDIR}/mcstransd.init" mcstransd
+}
-- 
cgit v1.2.3