From d42200bec37eef2a7478d88988ff00addd0a9202 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 25 Jan 2020 11:50:47 +0000
Subject: gentoo resync : 25.01.2020

---
 sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild | 66 +++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild

(limited to 'sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild')

diff --git a/sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild b/sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild
new file mode 100644
index 000000000000..9f6c5ecdfef1
--- /dev/null
+++ b/sys-apps/ipmiutil/ipmiutil-3.1.5.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools systemd
+
+DESCRIPTION="IPMI Management Utilities"
+HOMEPAGE="http://ipmiutil.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/openssl-1:0="
+DEPEND="${RDEPEND}
+	virtual/os-headers"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.9.8-flags.patch
+	"${FILESDIR}"/${PN}-2.9.9-lib_symlink.patch
+	"${FILESDIR}"/${PN}-3.1.4-fix_lanplus_build.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's|-O2 -g|$(CFLAGS)|g;s|-g -O2|$(CFLAGS)|g' util/Makefile.am* || die
+	sed -i -e 's|which rpm |which we_are_gentoo_rpm_is_a_guest |' configure.ac || die
+
+	# Don't compress man pages
+	sed '/gzip -f/d' -i doc/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-systemd --enable-sha256 --enable-lanplus
+}
+
+src_compile() {
+	# Ulgy workaround. Upstream is misusing the make system here
+	# and it doesn't even work.
+	# Please check on each bump if this workaround is still required.
+	pushd lib/lanplus &>/dev/null || die
+	emake
+	cp libipmi_lanplus.a .. || die
+	popd &>/dev/null || die
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" sysdto="${D}/$(systemd_get_systemunitdir)" install
+	dodoc -r AUTHORS ChangeLog NEWS README TODO doc/UserGuide
+
+	# Init scripts are only for Fedora
+	rm -r "${ED}"/etc/init.d || die 'remove initscripts failed'
+
+	if ! use static-libs ; then
+		find "${ED}" -type f -name '*.a' -delete || die
+	fi
+
+	keepdir /var/lib/ipmiutil
+}
-- 
cgit v1.2.3