From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 sys-apps/edac-utils/edac-utils-0.18-r1.ebuild | 53 +++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 sys-apps/edac-utils/edac-utils-0.18-r1.ebuild

(limited to 'sys-apps/edac-utils/edac-utils-0.18-r1.ebuild')

diff --git a/sys-apps/edac-utils/edac-utils-0.18-r1.ebuild b/sys-apps/edac-utils/edac-utils-0.18-r1.ebuild
new file mode 100644
index 000000000000..b48d523eff5d
--- /dev/null
+++ b/sys-apps/edac-utils/edac-utils-0.18-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Userspace helper for Linux kernel EDAC drivers"
+HOMEPAGE="https://github.com/grondo/edac-utils"
+SRC_URI="https://github.com/grondo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="debug"
+
+DEPEND="sys-fs/sysfsutils"
+RDEPEND="${DEPEND}
+	sys-apps/dmidecode"
+
+src_prepare() {
+	default
+
+	# Needed to refresh libtool and friends to not call CC directly
+	# bug #725540
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	# Dump the inappropriate-for-us bundled init script
+	rm -rf "${ED}/etc/init.d" || die
+
+	# Install our own
+	newinitd "${FILESDIR}"/edac.init edac
+	systemd_dounit "${FILESDIR}"/edac.service
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "There must be an entry for your mainboard in ${EROOT}/etc/edac/labels.db"
+	elog "in case you want nice labels in /sys/module/*_edac/"
+	elog "Run the following command to check whether such an entry is already available:"
+	elog "    edac-ctl --print-labels"
+}
-- 
cgit v1.2.3