From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 sys-apps/dtc/dtc-1.4.3.ebuild | 52 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 sys-apps/dtc/dtc-1.4.3.ebuild

(limited to 'sys-apps/dtc/dtc-1.4.3.ebuild')

diff --git a/sys-apps/dtc/dtc-1.4.3.ebuild b/sys-apps/dtc/dtc-1.4.3.ebuild
new file mode 100644
index 000000000000..d5288e84280a
--- /dev/null
+++ b/sys-apps/dtc/dtc-1.4.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit multilib toolchain-funcs eutils
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/dtc/dtc.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://kernel/software/utils/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="Open Firmware device tree compiler"
+HOMEPAGE="https://devicetree.org/ https://git.kernel.org/cgit/utils/dtc/dtc.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="static-libs"
+
+DEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+DOCS="
+	Documentation/dt-object-internal.txt
+	Documentation/dts-format.txt
+	Documentation/manual.txt
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^CFLAGS =/s:=:+=:' \
+		-e '/^CPPFLAGS =/s:=:+=:' \
+		-e 's:-Werror::' \
+		-e 's:-g -Os::' \
+		-e "/^PREFIX =/s:=.*:= ${EPREFIX}/usr:" \
+		-e "/^LIBDIR =/s:=.*:= \$(PREFIX)/$(get_libdir):" \
+		Makefile || die
+
+	tc-export AR CC
+	export V=1
+}
+
+src_install() {
+	default
+
+	use static-libs || find "${ED}" -name '*.a' -delete
+}
-- 
cgit v1.2.3