From 09f46eb2a6639c039b0b4268a8410d93bbf14e9e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 3 Apr 2023 17:20:42 +0100
Subject: gentoo auto-resync : 03:04:2023 - 17:20:42

---
 sys-apps/cpu-x/cpu-x-4.5.3.ebuild | 80 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 sys-apps/cpu-x/cpu-x-4.5.3.ebuild

(limited to 'sys-apps/cpu-x/cpu-x-4.5.3.ebuild')

diff --git a/sys-apps/cpu-x/cpu-x-4.5.3.ebuild b/sys-apps/cpu-x/cpu-x-4.5.3.ebuild
new file mode 100644
index 000000000000..bcd8a36360ce
--- /dev/null
+++ b/sys-apps/cpu-x/cpu-x-4.5.3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://thetumultuousunicornofdarkness.github.io/CPU-X/"
+SRC_URI="https://github.com/TheTumultuousUnicornOfDarkness/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+cpu force-libstatgrab +gpu gui +ncurses +nls opencl +pci test vulkan"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gui? ( >=x11-libs/gtk+-3.12:3 )
+	cpu? ( >=dev-libs/libcpuid-0.6.0:= )
+	gpu? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	pci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+	vulkan? ( media-libs/vulkan-loader )
+"
+
+DEPEND="
+	test? (
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gui)
+		-DWITH_LIBCPUID=$(usex cpu)
+		-DWITH_LIBGLFW=$(usex gpu)
+		-DWITH_LIBPCI=$(usex pci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_VULKAN=$(usex vulkan)
+	)
+	use gui && mycmakeargs+=( -DGSETTINGS_COMPILE=OFF )
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3