From 3faa6ebe0068b432ee5a9390c47ceca068ea7fe9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 21 Mar 2024 07:00:13 +0000
Subject: gentoo auto-resync : 21:03:2024 - 07:00:13

---
 sys-apps/bleachbit/bleachbit-4.6.0.ebuild | 87 -------------------------------
 1 file changed, 87 deletions(-)
 delete mode 100644 sys-apps/bleachbit/bleachbit-4.6.0.ebuild

(limited to 'sys-apps/bleachbit/bleachbit-4.6.0.ebuild')

diff --git a/sys-apps/bleachbit/bleachbit-4.6.0.ebuild b/sys-apps/bleachbit/bleachbit-4.6.0.ebuild
deleted file mode 100644
index 2ce3db673047..000000000000
--- a/sys-apps/bleachbit/bleachbit-4.6.0.ebuild
+++ /dev/null
@@ -1,87 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} )
-PYTHON_REQ_USE="sqlite(+)"
-DISTUTILS_SINGLE_IMPL=1
-
-inherit desktop distutils-r1 virtualx
-
-DESCRIPTION="Clean junk to free disk space and to maintain privacy"
-HOMEPAGE="https://www.bleachbit.org"
-SRC_URI="https://download.bleachbit.org/${P}.tar.bz2"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 x86"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		dev-python/chardet[${PYTHON_USEDEP}]
-		dev-python/pygobject:3[${PYTHON_USEDEP}]
-	')
-	x11-libs/gtk+:3
-"
-BDEPEND="
-	sys-devel/gettext
-	test? (
-		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]')
-	)
-"
-
-distutils_enable_tests unittest
-
-# tests fail under FEATURES=usersandbox
-RESTRICT="test"
-
-python_prepare_all() {
-	if use test; then
-		# avoid tests requiring internet access
-		rm tests/Test{Chaff,Update}.py || die
-
-		# fails due to non-existent $HOME/.profile
-		rm tests/TestInit.py || die
-
-		# only applicable to Windows installer
-		rm tests/TestNsisUtilities.py || die
-
-		# these fail on upstream Travis CI as well as on Gentoo
-		sed -e "s/test_notify(self)/_&/" \
-			-i tests/TestGUI.py || die
-
-		sed -e "s/test_get_proc_swaps(self)/_&/" \
-			-i tests/TestMemory.py || die
-	fi
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	emake -C po local
-}
-
-python_test() {
-	virtx emake tests
-}
-
-python_install() {
-	distutils-r1_python_install
-	python_newscript ${PN}.py ${PN}
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	emake -C po DESTDIR="${D}" install
-
-	insinto /usr/share/bleachbit/cleaners
-	doins cleaners/*.xml
-
-	insinto /usr/share/bleachbit
-	doins data/app-menu.ui
-
-	doicon ${PN}.png
-	domenu org.${PN}.BleachBit.desktop
-}
-- 
cgit v1.2.3