From 7a86906b67693cc65671d3e1476835d3a7e13092 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 22 Jun 2019 11:40:06 +0100
Subject: gentoo resync : 22.06.2019

---
 .../tensorboard/tensorboard-1.14.0.ebuild          | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sci-visualization/tensorboard/tensorboard-1.14.0.ebuild

(limited to 'sci-visualization')

diff --git a/sci-visualization/tensorboard/tensorboard-1.14.0.ebuild b/sci-visualization/tensorboard/tensorboard-1.14.0.ebuild
new file mode 100644
index 000000000000..1e9df6f9ed23
--- /dev/null
+++ b/sci-visualization/tensorboard/tensorboard-1.14.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Jason Zaman
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit python-r1 python-utils-r1
+
+DESCRIPTION="TensorFlow's Visualization Toolkit"
+HOMEPAGE="https://www.tensorflow.org/"
+SRC_URI="https://files.pythonhosted.org/packages/py3/${PN::1}/${PN}/${P}-py3-none-any.whl -> ${P}.zip"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/grpcio[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]"
+BDEPEND="app-arch/unzip"
+PDEPEND="sci-libs/tensorflow[python,${PYTHON_USEDEP}]"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	eapply_user
+
+	rm -rf "${S}/${PN}/_vendor/bleach" || die
+	rm -rf "${S}/${PN}/_vendor/html5lib" || die
+	sed -i -e '/_vendor.bleach/d' -e '/_vendor.html5lib/d' "${S}/${P}.dist-info/RECORD" || die "failed to unvendor"
+
+	find "${S}/${PN}" -name '*.py' -exec sed -i \
+		-e 's/^from tensorboard\._vendor import html5lib/import html5lib/' \
+		-e 's/^from tensorboard\._vendor import bleach/import bleach/' \
+		-e 's/^from tensorboard\._vendor\.html5lib/from html5lib/' \
+		-e 's/^from tensorboard\._vendor\.bleach/from bleach/' \
+		{} + || die "failed to unvendor"
+}
+
+src_install() {
+	do_install() {
+		python_domodule "${PN}"
+		python_domodule "${P}.dist-info"
+	}
+	python_foreach_impl do_install
+}
-- 
cgit v1.2.3