From d42200bec37eef2a7478d88988ff00addd0a9202 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 25 Jan 2020 11:50:47 +0000
Subject: gentoo resync : 25.01.2020

---
 sci-visualization/gwyddion/gwyddion-2.55.ebuild | 75 +++++++++++++++++++++++++
 1 file changed, 75 insertions(+)
 create mode 100644 sci-visualization/gwyddion/gwyddion-2.55.ebuild

(limited to 'sci-visualization/gwyddion/gwyddion-2.55.ebuild')

diff --git a/sci-visualization/gwyddion/gwyddion-2.55.ebuild b/sci-visualization/gwyddion/gwyddion-2.55.ebuild
new file mode 100644
index 000000000000..38eb5f9eca44
--- /dev/null
+++ b/sci-visualization/gwyddion/gwyddion-2.55.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils xdg
+
+DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fits gnome nls openexr opengl perl ruby sourceview xml X"
+
+RDEPEND="
+	>=dev-libs/glib-2.32
+	dev-libs/libzip
+	media-libs/libpng:0=
+	>=sci-libs/fftw-3.1:3.0=
+	x11-libs/cairo
+	>=x11-libs/gtk+-2.18:2
+	x11-libs/libXmu
+	x11-libs/pango
+	fits? ( sci-libs/cfitsio )
+	gnome? ( gnome-base/gconf:2 )
+	openexr? ( media-libs/openexr:= )
+	opengl? ( virtual/opengl x11-libs/gtkglext )
+	perl? ( dev-lang/perl:= )
+	ruby? ( dev-ruby/narray )
+	sourceview? ( x11-libs/gtksourceview:2.0 )
+	xml? ( dev-libs/libxml2:2 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.55-automagic.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-rpath \
+		--without-kde4-thumbnailer \
+		$(use_enable doc gtk-doc) \
+		$(use_enable nls) \
+		--disable-pygwy \
+		$(use_with fits cfitsio) \
+		$(use_with perl) \
+		--without-python \
+		$(use_with ruby) \
+		$(use_with opengl gl) \
+		$(use_with openexr exr) \
+		$(use_with sourceview gtksourceview) \
+		$(use_with xml libxml2) \
+		$(use_with X x) \
+		--with-zip=libzip
+}
+
+pkg_postinst() {
+	use gnome && gnome2_gconf_install
+	xdg_pkg_postinst
+}
+
+pkg_prerm() {
+	use gnome && gnome2_gconf_uninstall
+}
-- 
cgit v1.2.3