From 30f491533785a455cdfbd05bb57f1f869a8e41bb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 10 Jan 2023 06:19:57 +0000
Subject: gentoo auto-resync : 10:01:2023 - 06:19:57

---
 sci-physics/reduze/reduze-2.4-r1.ebuild | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 sci-physics/reduze/reduze-2.4-r1.ebuild

(limited to 'sci-physics/reduze/reduze-2.4-r1.ebuild')

diff --git a/sci-physics/reduze/reduze-2.4-r1.ebuild b/sci-physics/reduze/reduze-2.4-r1.ebuild
new file mode 100644
index 000000000000..218b666b890d
--- /dev/null
+++ b/sci-physics/reduze/reduze-2.4-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Program for reducing Feynman integrals"
+HOMEPAGE="https://reduze.hepforge.org/"
+SRC_URI="https://reduze.hepforge.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="berkdb doc examples mpi"
+
+RDEPEND="
+	>=sci-mathematics/ginac-1.4.1
+	berkdb? ( sys-libs/db:5.3=[cxx] )
+	mpi? ( virtual/mpi )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-cmake.patch
+	"${FILESDIR}"/${PN}-2.2-db.patch
+)
+
+# remove bundled yaml-cpp
+# no: it does not build. is it patched?
+# sed -i -e '/add_subdirectory ("yaml")/d' CMakeLists.txt || die
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON # no thanks
+		-DUSE_HASH_TABLE=ON
+		-DUSE_DATABASE=$(usex berkdb)
+		-DENABLE_EXAMPLES=$(usex examples)
+		-DUSE_MPI=$(usex mpi)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all $(usev doc)
+}
+
+src_test() {
+	cmake_build check
+	use mpi && cmake_build check_mpi
+}
+
+src_install() {
+	use doc && local HTML_DOCS+=( "${BUILD_DIR}"/doc/code/html/. )
+	cmake_src_install
+}
-- 
cgit v1.2.3