From 9bd54251864651f49e673a08aec9ef79cfe08f04 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 17 Dec 2017 09:07:15 +0000
Subject: gentoo resync : 17.12.2017

---
 sci-physics/reduze/reduze-2.2.ebuild | 65 ++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 sci-physics/reduze/reduze-2.2.ebuild

(limited to 'sci-physics/reduze/reduze-2.2.ebuild')

diff --git a/sci-physics/reduze/reduze-2.2.ebuild b/sci-physics/reduze/reduze-2.2.ebuild
new file mode 100644
index 000000000000..37b323c903b1
--- /dev/null
+++ b/sci-physics/reduze/reduze-2.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Program for reducing Feynman integrals"
+HOMEPAGE="http://reduze.hepforge.org/"
+SRC_URI="http://reduze.hepforge.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="berkdb doc mpi"
+
+RDEPEND=">=sci-mathematics/ginac-1.4.1
+	berkdb? ( sys-libs/db:6.0[cxx] )
+	mpi? ( virtual/mpi )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# gentoo doc directory
+	sed -i \
+		-e "s:share/reduze:share/doc/${PF}:g" \
+		CMakeLists.txt || die
+	if ! use doc ; then
+		sed -i -e '/share/d' CMakeLists.txt || die
+	fi
+	# prefix fix
+	sed -i \
+		-e "s:/usr:${EPREFIX}/usr:g" \
+		reduze/CMakeLists.txt  || die
+
+	# remove bundled yaml-cpp
+	# no: it does not build. is it patched?
+	# sed -i -e '/add_subdirectory ("yaml")/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_HASH_TABLE=ON
+		-DUSE_DATABASE=$(usex berkdb)
+		-DUSE_MPI=$(usex mpi)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile all $(usev doc)
+}
+
+src_test() {
+	cmake-utils_src_compile check
+	use mpi && cmake-utils_src_compile check_mpi
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( "${BUILD_DIR}"/doc/code/html/. )
+	cmake-utils_src_install
+}
-- 
cgit v1.2.3