From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 sci-physics/lhapdf/lhapdf-6.5.1.ebuild | 57 ++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 sci-physics/lhapdf/lhapdf-6.5.1.ebuild

(limited to 'sci-physics/lhapdf/lhapdf-6.5.1.ebuild')

diff --git a/sci-physics/lhapdf/lhapdf-6.5.1.ebuild b/sci-physics/lhapdf/lhapdf-6.5.1.ebuild
new file mode 100644
index 000000000000..fd63f215565d
--- /dev/null
+++ b/sci-physics/lhapdf/lhapdf-6.5.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_9 )
+DOCS_BUILDER="doxygen"
+DOCS_DEPEND="
+	dev-texlive/texlive-bibtexextra
+	dev-texlive/texlive-fontsextra
+	dev-texlive/texlive-fontutils
+	dev-texlive/texlive-latex
+	dev-texlive/texlive-latexextra
+"
+inherit python-single-r1 docs
+
+MY_PV=$(ver_cut 1-3)
+MY_PF=LHAPDF-${MY_PV}
+
+DESCRIPTION="Les Houches Parton Density Function unified library"
+HOMEPAGE="https://lhapdf.hepforge.org/"
+SRC_URI="https://www.hepforge.org/downloads/lhapdf/${MY_PF}.tar.gz"
+S="${WORKDIR}/${MY_PF}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/boost:0=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	CONFIG_SHELL="${EPREFIX}/bin/bash" \
+	econf \
+		--disable-static \
+		--enable-python
+}
+
+src_compile() {
+	emake all $(use doc && echo doxy)
+}
+
+src_test() {
+	emake -C tests
+}
+
+src_install() {
+	default
+	use doc && dodoc -r doc/doxygen/.
+	use examples && dodoc examples/*.cc
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3