From 752d6256e5204b958b0ef7905675a940b5e9172f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 12 May 2022 16:42:50 +0300
Subject: gentoo resync : 12.05.2022

---
 .../coq-serapi/coq-serapi-0.15.0-r2.ebuild         | 64 ++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 sci-mathematics/coq-serapi/coq-serapi-0.15.0-r2.ebuild

(limited to 'sci-mathematics/coq-serapi/coq-serapi-0.15.0-r2.ebuild')

diff --git a/sci-mathematics/coq-serapi/coq-serapi-0.15.0-r2.ebuild b/sci-mathematics/coq-serapi/coq-serapi-0.15.0-r2.ebuild
new file mode 100644
index 000000000000..2290f780d192
--- /dev/null
+++ b/sci-mathematics/coq-serapi/coq-serapi-0.15.0-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COQV=8.15.0
+
+inherit elisp-common dune
+
+DESCRIPTION="Serialization library and protocol for interaction with the Coq proof assistant"
+HOMEPAGE="https://github.com/ejgallego/coq-serapi/"
+# The tarball in SRC_URI is comprised of <supported coq>+<package version>
+SRC_URI="https://github.com/ejgallego/${PN}/archive/${COQV}+${PV}.tar.gz
+		-> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${COQV}-${PV}
+
+LICENSE="GPL-3+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="emacs +ocamlopt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sci-mathematics/coq-${COQV}:=
+	>=dev-ml/ppx_sexp_conv-0.13.0:= <dev-ml/ppx_sexp_conv-0.15.0:=
+	dev-ml/cmdliner:=
+	dev-ml/ppx_deriving:=
+	dev-ml/ppx_deriving_yojson:=
+	dev-ml/ppx_import:=
+	dev-ml/sexplib:=
+	dev-ml/yojson:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+	test? ( sci-mathematics/coq-mathcomp )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-sertop.el-path.patch )
+SITEFILE="50sertop-gentoo.el"
+
+src_compile() {
+	dune_src_compile
+
+	use emacs && elisp-compile sertop.el
+}
+
+src_install() {
+	dune_src_install
+
+	rm -r "${D}"/usr/share/emacs || die
+	if use emacs ; then
+		elisp-install ${PN} sertop.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3