From bb8c9132545ddf1e366b0b478c0dc89c56cf6dcd Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 4 Jun 2023 15:34:41 +0100
Subject: gentoo auto-resync : 04:06:2023 - 15:34:41

---
 sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild | 76 ++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild

(limited to 'sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild')

diff --git a/sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild b/sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild
new file mode 100644
index 000000000000..1ba42319bb6c
--- /dev/null
+++ b/sci-mathematics/alt-ergo/alt-ergo-2.4.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune
+
+DESCRIPTION="Automatic theorem prover"
+HOMEPAGE="https://alt-ergo.ocamlpro.com
+	https://github.com/OCamlPro/alt-ergo/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/OCamlPro/${PN}.git"
+else
+	SRC_URI="https://github.com/OCamlPro/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="CeCILL-C"
+SLOT="0/${PV}"
+IUSE="examples gui +ocamlopt"
+REQUIRED_USE="ocamlopt"
+
+RDEPEND="
+	>=dev-lang/ocaml-4.09.0:=[ocamlopt=]
+	>=sci-mathematics/psmt2-frontend-0.4.0:=
+
+	>=dev-ml/cmdliner-1.1.0:=
+	>=dev-ml/menhir-20181006:=
+	>=dev-ml/ocplib-simplex-0.4:=
+	dev-ml/camlzip:=
+	dev-ml/num:=
+	dev-ml/stdlib-shims:=
+	dev-ml/zarith:=
+	gui? (
+		dev-ml/lablgtk:3
+		dev-ml/lablgtk-sourceview:3
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-ml/dune-build-info
+	dev-ml/dune-configurator
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.4.3-dune.patch )
+
+OCAML_SUBPACKAGES=(
+	alt-ergo-lib
+	alt-ergo-parsers
+	alt-ergo
+)
+
+src_prepare() {
+	default
+
+	if use gui ; then
+		OCAML_SUBPACKAGES+=( altgr-ergo )
+	fi
+}
+
+src_configure() {
+	sh ./configure --prefix /usr --libdir=/usr/$(get_libdir) || die
+}
+
+src_compile() {
+	dune-compile ${OCAML_SUBPACKAGES[@]}
+}
+
+src_install() {
+	dune-install ${OCAML_SUBPACKAGES[@]}
+
+	use examples && dodoc -r examples
+}
-- 
cgit v1.2.3