From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 sci-libs/votca-tools/votca-tools-9999.ebuild | 59 ++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 sci-libs/votca-tools/votca-tools-9999.ebuild

(limited to 'sci-libs/votca-tools/votca-tools-9999.ebuild')

diff --git a/sci-libs/votca-tools/votca-tools-9999.ebuild b/sci-libs/votca-tools/votca-tools-9999.ebuild
new file mode 100644
index 000000000000..1902116de670
--- /dev/null
+++ b/sci-libs/votca-tools/votca-tools-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+CMAKE_MAKEFILE_GENERATOR="ninja"
+
+inherit cmake-utils eutils multilib
+
+if [ "${PV}" != "9999" ]; then
+	SRC_URI="https://github.com/${PN/-//}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-macos"
+	S="${WORKDIR}/${P#votca-}"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN/-//}.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="Votca tools library"
+HOMEPAGE="http://www.votca.org"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc +fftw +gsl sqlite"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/expat
+	fftw? ( sci-libs/fftw:3.0 )
+	gsl? ( sci-libs/gsl )
+	sqlite? ( dev-db/sqlite:3 )"
+
+DEPEND="${RDEPEND}
+	doc? ( >=app-doc/doxygen-1.7.6.1[dot] )
+	>=app-text/txt2tags-2.5
+	virtual/pkgconfig"
+
+DOCS=( NOTICE )
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_GSL=$(usex gsl)
+		-DWITH_FFTW=$(usex fftw)
+		-DWITH_SQLITE3=$(usex sqlite)
+		-DWITH_RC_FILES=OFF
+		-DLIB=$(get_libdir)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use doc; then
+		cd "${CMAKE_BUILD_DIR}"
+		cmake-utils_src_make html
+		dodoc -r share/doc/html
+	fi
+}
-- 
cgit v1.2.3