From 752d6256e5204b958b0ef7905675a940b5e9172f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 12 May 2022 16:42:50 +0300
Subject: gentoo resync : 12.05.2022

---
 sci-libs/pdal/pdal-2.4.0-r1.ebuild | 56 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sci-libs/pdal/pdal-2.4.0-r1.ebuild

(limited to 'sci-libs/pdal/pdal-2.4.0-r1.ebuild')

diff --git a/sci-libs/pdal/pdal-2.4.0-r1.ebuild b/sci-libs/pdal/pdal-2.4.0-r1.ebuild
new file mode 100644
index 000000000000..9bd82c4dc76e
--- /dev/null
+++ b/sci-libs/pdal/pdal-2.4.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A C++ library for translating and manipulating point cloud data"
+HOMEPAGE="https://pdal.io/"
+SRC_URI="https://github.com/PDAL/PDAL/releases/download/${PV}/PDAL-${PV}-src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/14"
+KEYWORDS="~amd64 ~x86"
+IUSE="postgres test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+RDEPEND="
+	net-misc/curl
+	app-arch/zstd:=
+	dev-libs/libxml2
+	dev-libs/openssl:=
+	sci-libs/gdal:=
+	sci-libs/libgeotiff:=
+	sys-libs/libunwind:=
+	sys-libs/zlib
+	postgres? ( dev-db/postgresql:*[xml] )
+"
+DEPEND="
+	test? ( sci-libs/gdal[geos,jpeg,png] )
+	${RDEPEND}
+"
+
+S="${WORKDIR}/PDAL-${PV}-src"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLUGIN_PGPOINTCLOUD="$(usex postgres)"
+		-DWITH_COMPLETION=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		--exclude-regex '(pgpointcloudtest|pdal_io_bpf_base_test|pdal_io_bpf_zlib_test|pdal_filters_overlay_test|pdal_filters_stats_test|pdal_app_plugin_test|pdal_merge_test)'
+		--output-on-failure
+	)
+
+	cmake_src_test
+}
-- 
cgit v1.2.3