From 7d1fc8f13082082c2539f20beadcf37089543b8e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 20 Jun 2023 07:15:41 +0100
Subject: gentoo auto-resync : 20:06:2023 - 07:15:40

---
 sci-libs/libsc/libsc-2.8.5-r2.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 sci-libs/libsc/libsc-2.8.5-r2.ebuild

(limited to 'sci-libs/libsc/libsc-2.8.5-r2.ebuild')

diff --git a/sci-libs/libsc/libsc-2.8.5-r2.ebuild b/sci-libs/libsc/libsc-2.8.5-r2.ebuild
new file mode 100644
index 000000000000..786ecf6012b8
--- /dev/null
+++ b/sci-libs/libsc/libsc-2.8.5-r2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="Support for parallel scientific applications"
+HOMEPAGE="http://www.p4est.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/cburstedde/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://github.com/cburstedde/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="debug examples mpi openmp threads"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-libs/zlib-ng
+	virtual/blas
+	virtual/lapack
+	mpi? ( virtual/mpi[romio] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-set_version.patch
+	"${FILESDIR}"/${P}-fix_build_system.patch
+	"${FILESDIR}"/${P}-do_not_compile_zlib-ng.patch
+	"${FILESDIR}"/${P}-use_zlib-ng_symbols.patch
+	"${FILESDIR}"/${P}-fix_cmake_path.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Dmpi="$(usex mpi)"
+		-Dopenmp="$(usex openmp)"
+		-Dlibrary_reldir="$(get_libdir)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/include/getopt.h \
+		"${ED}"/usr/include/getopt_int.h \
+		"${ED}"/usr/include/sc_builtin || die "rm failed"
+
+	mv "${ED}"/usr/share/docs/SC/* "${ED}"/usr/share/doc/${PF}/ || die "mv failed"
+	rm -r "${ED}"/usr/share/docs || die "rm failed"
+}
-- 
cgit v1.2.3