From d42200bec37eef2a7478d88988ff00addd0a9202 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 25 Jan 2020 11:50:47 +0000
Subject: gentoo resync : 25.01.2020

---
 sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild

(limited to 'sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild')

diff --git a/sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild b/sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild
new file mode 100644
index 000000000000..5237072823ec
--- /dev/null
+++ b/sci-libs/libgeodecomp/libgeodecomp-0.4.0-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake cuda
+
+DESCRIPTION="An auto-parallelizing library to speed up computer simulations"
+HOMEPAGE="http://www.libgeodecomp.org"
+SRC_URI="http://www.libgeodecomp.org/archive/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="Boost-1.0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc mpi cuda opencl opencv silo hpx visit"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		app-text/texlive
+		media-gfx/graphviz
+		)"
+RDEPEND=">=dev-libs/boost-1.48"
+DEPEND="${RDEPEND}
+	hpx? ( sys-cluster/hpx )
+	<=dev-libs/libflatarray-0.2.0
+	mpi? ( virtual/mpi )
+	cuda? ( dev-util/nvidia-cuda-toolkit )
+	opencl? ( virtual/opencl )
+	opencv? ( media-libs/opencv )
+	silo? ( sci-libs/silo )"
+
+S="${WORKDIR}/${P}"
+PATCHES=(
+	"${FILESDIR}/${P}-scotch.patch"
+	"${FILESDIR}/${P}-libdir.patch"
+	"${FILESDIR}/${P}-lfa.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	use cuda && cuda_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MPI=$(usex mpi)
+		-DWITH_CUDA=$(usex cuda)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_OPENCV=$(usex opencv)
+		-DWITH_SILO=$(usex silo)
+		-DWITH_SCOTCH=false
+		-DWITH_HPX=$(usex hpx)
+		-DWITH_VISIT=false
+		-DWITH_TYPEMAPS=false
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build doc
+}
+
+src_install() {
+	DOCS=( README )
+	use doc && HTML_DOCS=( doc/html/* )
+	cmake_src_install
+}
+
+src_test() {
+	cmake_build check
+}
-- 
cgit v1.2.3