From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 sci-libs/libccd/libccd-2.1.ebuild | 59 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 sci-libs/libccd/libccd-2.1.ebuild

(limited to 'sci-libs/libccd/libccd-2.1.ebuild')

diff --git a/sci-libs/libccd/libccd-2.1.ebuild b/sci-libs/libccd/libccd-2.1.ebuild
new file mode 100644
index 000000000000..8691045954d5
--- /dev/null
+++ b/sci-libs/libccd/libccd-2.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [ "${PV}" = "9999" ] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/danfis/libccd/${PN}.git"
+else
+	SRC_URI="https://github.com/danfis/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm"
+fi
+
+DESCRIPTION="Library for collision detection between two convex shapes"
+HOMEPAGE="http://libccd.danfis.cz/
+	https://github.com/danfis/libccd"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="+double-precision doc +shared test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=""
+
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx )
+"
+
+src_prepare() {
+	# upstream issue 72
+	# https://github.com/danfis/libccd/issues/72
+	sed -i -e "s \${CMAKE_INSTALL_DATAROOTDIR}/doc/ccd \${CMAKE_INSTALL_DATAROOTDIR}/doc/${PF} g" \
+	CMakeLists.txt doc/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc ON OFF)
+		-DBUILD_SHARED_LIBS=$(usex shared ON OFF)
+		-DENABLE_DOUBLE_PRECISION=$(usex double-precision ON OFF)
+	)
+
+	local CMAKE_BUILD_TYPE="Release"
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		local DOCS=( "${BUILD_DIR}"/doc/man )
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/html )
+		einstalldocs
+	fi
+}
-- 
cgit v1.2.3