From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 sci-libs/libaec/libaec-1.0.6.ebuild | 44 +++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 sci-libs/libaec/libaec-1.0.6.ebuild

(limited to 'sci-libs/libaec/libaec-1.0.6.ebuild')

diff --git a/sci-libs/libaec/libaec-1.0.6.ebuild b/sci-libs/libaec/libaec-1.0.6.ebuild
new file mode 100644
index 000000000000..2c95da741a7c
--- /dev/null
+++ b/sci-libs/libaec/libaec-1.0.6.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit cmake
+
+MY_P="${PN}-v${PV}"
+DESCRIPTION="Adaptive Entropy Coding library"
+HOMEPAGE="https://gitlab.dkrz.de/k202009/libaec"
+SRC_URI="https://gitlab.dkrz.de/k202009/libaec/-/archive/v${PV}/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD-2"
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="+szip"
+
+RDEPEND="szip? ( !sci-libs/szip )"
+
+src_configure() {
+	mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR=$(get_libdir)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# avoid conflict with szip (easier than to patch)
+	if ! use szip; then
+		rm "${ED}"/usr/include/szlib.h || die
+		rm "${ED}"/usr/$(get_libdir)/libsz* || die
+		rm "${ED}"/usr/share/doc/${PF}/README.SZIP || die
+	fi
+
+	# Move these cmake files to a proper location
+	dodir "/usr/$(get_libdir)/cmake/${PN}"
+	mv "${ED}/usr/cmake/"* "${ED}/usr/$(get_libdir)/cmake/${PN}" || die
+	rm -r "${ED}/usr/cmake/" || die
+}
-- 
cgit v1.2.3