From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 sci-libs/geos/geos-3.11.0.ebuild | 46 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 sci-libs/geos/geos-3.11.0.ebuild

(limited to 'sci-libs/geos/geos-3.11.0.ebuild')

diff --git a/sci-libs/geos/geos-3.11.0.ebuild b/sci-libs/geos/geos-3.11.0.ebuild
new file mode 100644
index 000000000000..c18104f4fc50
--- /dev/null
+++ b/sci-libs/geos/geos-3.11.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Geometry engine library for Geographic Information Systems"
+HOMEPAGE="https://trac.osgeo.org/geos/"
+SRC_URI="https://download.osgeo.org/geos/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+		-DUSE_CCACHE=OFF
+
+		# bug #709368
+		$(usex arm '-DDISABLE_GEOS_INLINE=ON' '')
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use doc && cmake_src_compile docs
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc ; then
+		HTML_DOCS=( "${BUILD_DIR}"/doc/doxygen_docs/html/. )
+		einstalldocs
+	fi
+}
-- 
cgit v1.2.3