From b279bbe94522565b8feb19b8e5f377d3ea76f157 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 24 Mar 2018 10:19:03 +0000
Subject: gentoo resync : 24.03.2018

---
 sci-libs/arpack/arpack-9999.ebuild | 56 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 sci-libs/arpack/arpack-9999.ebuild

(limited to 'sci-libs/arpack/arpack-9999.ebuild')

diff --git a/sci-libs/arpack/arpack-9999.ebuild b/sci-libs/arpack/arpack-9999.ebuild
new file mode 100644
index 000000000000..56b384c53431
--- /dev/null
+++ b/sci-libs/arpack/arpack-9999.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils fortran-2 toolchain-funcs
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/opencollab/arpack-ng"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/opencollab/${PN}-ng/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+	S="${WORKDIR}/${PN}-ng-${PV}"
+fi
+
+DESCRIPTION="Arnoldi package library to solve large scale eigenvalue problems"
+HOMEPAGE="http://www.caam.rice.edu/software/ARPACK/ https://github.com/opencollab/arpack-ng"
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples mpi static-libs"
+
+RDEPEND="
+	virtual/blas
+	virtual/lapack
+	mpi? ( virtual/mpi[fortran] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)" \
+		--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)" \
+		$(use_enable mpi)
+}
+
+src_install() {
+	default
+
+	dodoc DOCUMENTS/*.doc
+	newdoc DOCUMENTS/README README.doc
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r EXAMPLES
+		if use mpi; then
+			insinto /usr/share/doc/${PF}/EXAMPLES/PARPACK
+			doins -r PARPACK/EXAMPLES/MPI
+		fi
+	fi
+}
-- 
cgit v1.2.3